arch/powerpc/cpu/mpc512x/u-boot.lds

   1 /*
   2  * (C) Copyright 2007-2010 DENX Software Engineering.
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22
  23 OUTPUT_ARCH(powerpc)
  24 SECTIONS
  25 {
  26   .text      :
  27   {
  28     arch/powerpc/cpu/mpc512x/start.o    (.text*)
  29     *(.text*)
  30     . = ALIGN(16);
  31     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  32   }
  33
  34   /* Read-write section, merged into data segment: */
  35   . = (. + 0x0FFF) & 0xFFFFF000;
  36   _erotext = .;
  37   PROVIDE (erotext = .);
  38   .reloc   :
  39   {
  40     KEEP(*(.got))
  41     _GOT2_TABLE_ = .;
  42     KEEP(*(.got2))
  43     _FIXUP_TABLE_ = .;
  44     KEEP(*(.fixup))
  45     *(.fixup)
  46   }
  47   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  48   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  49
  50   .data    :
  51   {
  52     *(.data*)
  53     *(.sdata*)
  54   }
  55   _edata  =  .;
  56   PROVIDE (edata = .);
  57
  58   . = .;
  59   __u_boot_cmd_start = .;
  60   .u_boot_cmd : { *(.u_boot_cmd) }
  61   __u_boot_cmd_end = .;
  62
  63
  64   . = .;
  65   __start___ex_table = .;
  66   __ex_table : { *(__ex_table) }
  67   __stop___ex_table = .;
  68
  69   . = ALIGN(4096);
  70   __init_begin = .;
  71   .text.init : { *(.text.init) }
  72   .data.init : { *(.data.init) }
  73   . = ALIGN(4096);
  74   __init_end = .;
  75
  76   __bss_start = .;
  77   .bss (NOLOAD)       :
  78   {
  79    *(.bss*)
  80    *(.sbss*)
  81    *(COMMON)
  82    . = ALIGN(4);
  83   }
  84   _end = . ;
  85   PROVIDE (end = .);
  86 }
  87 ENTRY(_start)