arch/powerpc/cpu/mpc83xx/u-boot.lds

   1 /*
   2  * (C) Copyright 2006-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9 SECTIONS
  10 {
  11   /* Read-only sections, merged into text segment: */
  12   .text      :
  13   {
  14     arch/powerpc/cpu/mpc83xx/start.o    (.text*)
  15     *(.text*)
  16     . = ALIGN(16);
  17     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  18   }
  19
  20   /* Read-write section, merged into data segment: */
  21   . = (. + 0x0FFF) & 0xFFFFF000;
  22   _erotext = .;
  23   PROVIDE (erotext = .);
  24   .reloc   :
  25   {
  26     _GOT2_TABLE_ = .;
  27     KEEP(*(.got2))
  28     KEEP(*(.got))
  29     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  30     _FIXUP_TABLE_ = .;
  31     KEEP(*(.fixup))
  32   }
  33   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  34   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  35
  36   .data    :
  37   {
  38     *(.data*)
  39     *(.sdata*)
  40   }
  41   _edata  =  .;
  42   PROVIDE (edata = .);
  43
  44   . = .;
  45
  46   . = ALIGN(4);
  47   .u_boot_list : {
  48         KEEP(*(SORT(.u_boot_list*)));
  49   }
  50
  51
  52   . = .;
  53   __start___ex_table = .;
  54   __ex_table : { *(__ex_table) }
  55   __stop___ex_table = .;
  56
  57   . = ALIGN(4096);
  58   __init_begin = .;
  59   .text.init : { *(.text.init) }
  60   .data.init : { *(.data.init) }
  61   . = ALIGN(4096);
  62   __init_end = .;
  63
  64   __bss_start = .;
  65   .bss (NOLOAD)       :
  66   {
  67    *(.bss*)
  68    *(.sbss*)
  69    *(COMMON)
  70    . = ALIGN(4);
  71   }
  72   __bss_end = . ;
  73   PROVIDE (end = .);
  74 }
  75 ENTRY(_start)