arch/powerpc/cpu/mpc85xx/u-boot-nand_spl.lds

   1 /*
   2  * (C) Copyright 2006
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de
   4  *
   5  * Copyright 2009 Freescale Semiconductor, Inc.
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 #include "config.h"     /* CONFIG_BOARDDIR */
  27
  28 OUTPUT_ARCH(powerpc)
  29 SECTIONS
  30 {
  31         . = 0xfff00000;
  32         .text : {
  33                 *(.text*)
  34         }
  35         _etext = .;
  36
  37         .reloc : {
  38                 _GOT2_TABLE_ = .;
  39                 KEEP(*(.got2))
  40                 _FIXUP_TABLE_ = .;
  41                 KEEP(*(.fixup))
  42         }
  43         __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  44         __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  45
  46         . = ALIGN(8);
  47         .data : {
  48                 *(.rodata*)
  49                 *(.data*)
  50                 *(.sdata*)
  51         }
  52         _edata  =  .;
  53
  54         . = ALIGN(8);
  55         __init_begin = .;
  56         __init_end = .;
  57 #if defined(CONFIG_FSL_IFC) /* Restrict bootpg at 4K boundry for IFC */
  58         .bootpg ADDR(.text) + 0x1000 :
  59         {
  60                 start.o (.bootpg)
  61         }
  62 #define RESET_VECTOR_OFFSET 0x1ffc /* IFC has 8K sram */
  63 #elif defined(CONFIG_FSL_ELBC)
  64 #define RESET_VECTOR_OFFSET 0xffc /* LBC has 4k sram */
  65 #else
  66 #error unknown NAND controller
  67 #endif
  68         .resetvec ADDR(.text) + RESET_VECTOR_OFFSET : {
  69                 KEEP(*(.resetvec))
  70         } = 0xffff
  71
  72         __bss_start = .;
  73         .bss : {
  74                 *(.sbss*)
  75                 *(.bss*)
  76         }
  77         __bss_end__ = .;
  78 }
  79 ASSERT(__init_end <= (0xfff00000 + RESET_VECTOR_OFFSET), "NAND bootstrap too big");