arch/x86/cpu/start.S

   1 /*
   2  *  U-boot - x86 Startup Code
   3  *
   4  * (C) Copyright 2008-2011
   5  * Graeme Russ, <graeme.russ@gmail.com>
   6  *
   7  * (C) Copyright 2002
   8  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
   9  *
  10  * SPDX-License-Identifier:     GPL-2.0+
  11  */
  12
  13 #include <config.h>
  14 #include <version.h>
  15 #include <asm/global_data.h>
  16 #include <asm/post.h>
  17 #include <asm/processor.h>
  18 #include <asm/processor-flags.h>
  19 #include <generated/generic-asm-offsets.h>
  20
  21 .section .text
  22 .code32
  23 .globl _start
  24 .type _start, @function
  25 .globl _x86boot_start
  26 _x86boot_start:
  27         /*
  28          * This is the fail safe 32-bit bootstrap entry point. The
  29          * following code is not executed from a cold-reset (actually, a
  30          * lot of it is, but from real-mode after cold reset. It is
  31          * repeated here to put the board into a state as close to cold
  32          * reset as necessary)
  33          */
  34         cli
  35         cld
  36
  37         /* Turn off cache (this might require a 486-class CPU) */
  38         movl    %cr0, %eax
  39         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  40         movl    %eax, %cr0
  41         wbinvd
  42
  43         /* Tell 32-bit code it is being entered from an in-RAM copy */
  44         movw    $GD_FLG_WARM_BOOT, %bx
  45         jmp     1f
  46 _start:
  47         /*
  48          * This is the 32-bit cold-reset entry point. Initialize %bx to 0
  49          * in case we're preceeded by some sort of boot stub.
  50          */
  51         movw    $GD_FLG_COLD_BOOT, %bx
  52 1:
  53         /* Save BIST */
  54         movl    %eax, %ebp
  55
  56         /* Load the segement registes to match the gdt loaded in start16.S */
  57         movl    $(X86_GDT_ENTRY_32BIT_DS * X86_GDT_ENTRY_SIZE), %eax
  58         movw    %ax, %fs
  59         movw    %ax, %ds
  60         movw    %ax, %gs
  61         movw    %ax, %es
  62         movw    %ax, %ss
  63
  64         /* Clear the interrupt vectors */
  65         lidt    blank_idt_ptr
  66
  67         /* Early platform init (setup gpio, etc ) */
  68         jmp     early_board_init
  69 .globl early_board_init_ret
  70 early_board_init_ret:
  71         post_code(POST_START)
  72
  73         /* Initialise Cache-As-RAM */
  74         jmp     car_init
  75 .globl car_init_ret
  76 car_init_ret:
  77         /*
  78          * We now have CONFIG_SYS_CAR_SIZE bytes of Cache-As-RAM (or SRAM,
  79          * or fully initialised SDRAM - we really don't care which)
  80          * starting at CONFIG_SYS_CAR_ADDR to be used as a temporary stack
  81          * and early malloc area. The MRC requires some space at the top.
  82          *
  83          * Stack grows down from top of CAR. We have:
  84          *
  85          * top-> CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE
  86          *      MRC area
  87          *      global_data
  88          *      x86 global descriptor table
  89          *      early malloc area
  90          *      stack
  91          * bottom-> CONFIG_SYS_CAR_ADDR
  92          */
  93         movl    $(CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE - 4), %esp
  94 #ifdef CONFIG_DCACHE_RAM_MRC_VAR_SIZE
  95         subl    $CONFIG_DCACHE_RAM_MRC_VAR_SIZE, %esp
  96 #endif
  97
  98         /* Reserve space on stack for global data */
  99         subl    $GENERATED_GBL_DATA_SIZE, %esp
 100
 101         /* Align global data to 16-byte boundary */
 102         andl    $0xfffffff0, %esp
 103         post_code(POST_START_STACK)
 104
 105         /* Zero the global data since it won't happen later */
 106         xorl    %eax, %eax
 107         movl    $GENERATED_GBL_DATA_SIZE, %ecx
 108         movl    %esp, %edi
 109         rep     stosb
 110
 111         /* Setup first parameter to setup_gdt, pointer to global_data */
 112         movl    %esp, %eax
 113
 114         /* Reserve space for global descriptor table */
 115         subl    $X86_GDT_SIZE, %esp
 116
 117         /* Align temporary global descriptor table to 16-byte boundary */
 118         andl    $0xfffffff0, %esp
 119         movl    %esp, %ecx
 120
 121 #if defined(CONFIG_SYS_MALLOC_F_LEN)
 122         subl    $CONFIG_SYS_MALLOC_F_LEN, %esp
 123         movl    %eax, %edx
 124         addl    $GD_MALLOC_BASE, %edx
 125         movl    %esp, (%edx)
 126 #endif
 127         /* Store BIST */
 128         movl    %eax, %edx
 129         addl    $GD_BIST, %edx
 130         movl    %ebp, (%edx)
 131
 132         /* Set second parameter to setup_gdt */
 133         movl    %ecx, %edx
 134
 135         /* Setup global descriptor table so gd->xyz works */
 136         call    setup_gdt
 137
 138         /* Set parameter to board_init_f() to boot flags */
 139         post_code(POST_START_DONE)
 140         xorl    %eax, %eax
 141
 142         /* Enter, U-boot! */
 143         call    board_init_f
 144
 145         /* indicate (lack of) progress */
 146         movw    $0x85, %ax
 147         jmp     die
 148
 149 .globl board_init_f_r_trampoline
 150 .type board_init_f_r_trampoline, @function
 151 board_init_f_r_trampoline:
 152         /*
 153          * SDRAM has been initialised, U-Boot code has been copied into
 154          * RAM, BSS has been cleared and relocation adjustments have been
 155          * made. It is now time to jump into the in-RAM copy of U-Boot
 156          *
 157          * %eax = Address of top of new stack
 158          */
 159
 160         /* Stack grows down from top of SDRAM */
 161         movl    %eax, %esp
 162
 163         /* Reserve space on stack for global data */
 164         subl    $GENERATED_GBL_DATA_SIZE, %esp
 165
 166         /* Align global data to 16-byte boundary */
 167         andl    $0xfffffff0, %esp
 168
 169         /* Setup first parameter to memcpy (and setup_gdt) */
 170         movl    %esp, %eax
 171
 172         /* Setup second parameter to memcpy */
 173         fs movl 0, %edx
 174
 175         /* Set third parameter to memcpy */
 176         movl    $GENERATED_GBL_DATA_SIZE, %ecx
 177
 178         /* Copy global data from CAR to SDRAM stack */
 179         call    memcpy
 180
 181         /* Reserve space for global descriptor table */
 182         subl    $X86_GDT_SIZE, %esp
 183
 184         /* Align global descriptor table to 16-byte boundary */
 185         andl    $0xfffffff0, %esp
 186
 187         /* Set second parameter to setup_gdt */
 188         movl    %esp, %edx
 189
 190         /* Setup global descriptor table so gd->xyz works */
 191         call    setup_gdt
 192
 193         /* Re-enter U-Boot by calling board_init_f_r */
 194         call    board_init_f_r
 195
 196 die:
 197         hlt
 198         jmp     die
 199         hlt
 200
 201 blank_idt_ptr:
 202         .word   0               /* limit */
 203         .long   0               /* base */
 204
 205         .p2align        2       /* force 4-byte alignment */
 206
 207 multiboot_header:
 208         /* magic */
 209         .long   0x1BADB002
 210         /* flags */
 211         .long   (1 << 16)
 212         /* checksum */
 213         .long   -0x1BADB002 - (1 << 16)
 214         /* header addr */
 215         .long   multiboot_header - _x86boot_start + CONFIG_SYS_TEXT_BASE
 216         /* load addr */
 217         .long   CONFIG_SYS_TEXT_BASE
 218         /* load end addr */
 219         .long   0
 220         /* bss end addr */
 221         .long   0
 222         /* entry addr */
 223         .long   CONFIG_SYS_TEXT_BASE