arch/x86/cpu/start16.S

   1 /*
   2  *  U-boot - x86 Startup Code
   3  *
   4  * (C) Copyright 2008-2011
   5  * Graeme Russ, <graeme.russ@gmail.com>
   6  *
   7  * (C) Copyright 2002,2003
   8  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
   9  *
  10  * SPDX-License-Identifier:     GPL-2.0+
  11  */
  12
  13 #include <asm/global_data.h>
  14 #include <asm/processor-flags.h>
  15
  16 #define BOOT_SEG        0xffff0000      /* linear segment of boot code */
  17 #define a32             .byte 0x67;
  18 #define o32             .byte 0x66;
  19
  20 .section .start16, "ax"
  21 .code16
  22 .globl start16
  23 start16:
  24         /* Set the Cold Boot / Hard Reset flag */
  25         movl    $GD_FLG_COLD_BOOT, %ebx
  26
  27         /*
  28          * First we let the BSP do some early initialization
  29          * this code have to map the flash to its final position
  30          */
  31         jmp     board_init16
  32 .globl board_init16_ret
  33 board_init16_ret:
  34
  35         /* Turn of cache (this might require a 486-class CPU) */
  36         movl    %cr0, %eax
  37         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  38         movl    %eax, %cr0
  39         wbinvd
  40
  41         /* load the temporary Global Descriptor Table */
  42 o32 cs  lidt    idt_ptr
  43 o32 cs  lgdt    gdt_ptr
  44
  45         /* Now, we enter protected mode */
  46         movl    %cr0, %eax
  47         orl     $X86_CR0_PE, %eax
  48         movl    %eax, %cr0
  49
  50         /* Flush the prefetch queue */
  51         jmp     ff
  52 ff:
  53         /* Finally jump to the 32bit initialization code */
  54         movw    $code32start, %ax
  55         movw    %ax, %bp
  56 o32 cs  ljmp    *(%bp)
  57
  58         /* 48-bit far pointer */
  59 code32start:
  60         .long   _start          /* offset */
  61         .word   0x10            /* segment */
  62
  63 idt_ptr:
  64         .word   0               /* limit */
  65         .long   0               /* base */
  66
  67 /*
  68  * The following Global Descriptor Table is just enough to get us into
  69  * 'Flat Protected Mode' - It will be discarded as soon as the final
  70  * GDT is setup in a safe location in RAM
  71  */
  72 gdt_ptr:
  73         .word   0x1f            /* limit (31 bytes = 4 GDT entries - 1) */
  74         .long   BOOT_SEG + gdt  /* base */
  75
  76 /* Some CPUs are picky about GDT alignment... */
  77 .align 16
  78 gdt:
  79         /*
  80          * The GDT table ...
  81          *
  82          *       Selector       Type
  83          *       0x00           NULL
  84          *       0x08           Unused
  85          *       0x10           32bit code
  86          *       0x18           32bit data/stack
  87          */
  88         /* The NULL Desciptor - Mandatory */
  89         .word   0x0000          /* limit_low */
  90         .word   0x0000          /* base_low */
  91         .byte   0x00            /* base_middle */
  92         .byte   0x00            /* access */
  93         .byte   0x00            /* flags + limit_high */
  94         .byte   0x00            /* base_high */
  95
  96         /* Unused Desciptor - (matches Linux) */
  97         .word   0x0000          /* limit_low */
  98         .word   0x0000          /* base_low */
  99         .byte   0x00            /* base_middle */
 100         .byte   0x00            /* access */
 101         .byte   0x00            /* flags + limit_high */
 102         .byte   0x00            /* base_high */
 103
 104         /*
 105          * The Code Segment Descriptor:
 106          * - Base   = 0x00000000
 107          * - Size   = 4GB
 108          * - Access = Present, Ring 0, Exec (Code), Readable
 109          * - Flags  = 4kB Granularity, 32-bit
 110          */
 111         .word   0xffff          /* limit_low */
 112         .word   0x0000          /* base_low */
 113         .byte   0x00            /* base_middle */
 114         .byte   0x9b            /* access */
 115         .byte   0xcf            /* flags + limit_high */
 116         .byte   0x00            /* base_high */
 117
 118         /*
 119          * The Data Segment Descriptor:
 120          * - Base   = 0x00000000
 121          * - Size   = 4GB
 122          * - Access = Present, Ring 0, Non-Exec (Data), Writable
 123          * - Flags  = 4kB Granularity, 32-bit
 124          */
 125         .word   0xffff          /* limit_low */
 126         .word   0x0000          /* base_low */
 127         .byte   0x00            /* base_middle */
 128         .byte   0x93            /* access */
 129         .byte   0xcf            /* flags + limit_high */
 130         .byte   0x00            /* base_high */