board/LEOX/elpt860/u-boot.lds

   1 /*
   2 **=====================================================================
   3 **
   4 ** Copyright (C) 2000, 2001, 2002, 2003
   5 ** The LEOX team <team@leox.org>, http://www.leox.org
   6 **
   7 ** LEOX.org is about the development of free hardware and software resources
   8 **   for system on chip.
   9 **
  10 ** Description: U-Boot port on the LEOX's ELPT860 CPU board
  11 ** ~~~~~~~~~~~
  12 **
  13 **=====================================================================
  14 **
  15 ** This program is free software; you can redistribute it and/or
  16 ** modify it under the terms of the GNU General Public License as
  17 ** published by the Free Software Foundation; either version 2 of
  18 ** the License, or (at your option) any later version.
  19 **
  20 ** This program is distributed in the hope that it will be useful,
  21 ** but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ** MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ** GNU General Public License for more details.
  24 **
  25 ** You should have received a copy of the GNU General Public License
  26 ** along with this program; if not, write to the Free Software
  27 ** Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  28 ** MA 02111-1307 USA
  29 **
  30 **=====================================================================
  31 */
  32
  33 OUTPUT_ARCH(powerpc)
  34 /* Do we need any of these for elf?
  35    __DYNAMIC = 0;    */
  36 SECTIONS
  37 {
  38   /* Read-only sections, merged into text segment: */
  39   . = + SIZEOF_HEADERS;
  40   .interp : { *(.interp) }
  41   .hash          : { *(.hash)           }
  42   .dynsym        : { *(.dynsym)         }
  43   .dynstr        : { *(.dynstr)         }
  44   .rel.text      : { *(.rel.text)               }
  45   .rela.text     : { *(.rela.text)      }
  46   .rel.data      : { *(.rel.data)               }
  47   .rela.data     : { *(.rela.data)      }
  48   .rel.rodata    : { *(.rel.rodata)     }
  49   .rela.rodata   : { *(.rela.rodata)    }
  50   .rel.got       : { *(.rel.got)                }
  51   .rela.got      : { *(.rela.got)               }
  52   .rel.ctors     : { *(.rel.ctors)      }
  53   .rela.ctors    : { *(.rela.ctors)     }
  54   .rel.dtors     : { *(.rel.dtors)      }
  55   .rela.dtors    : { *(.rela.dtors)     }
  56   .rel.bss       : { *(.rel.bss)                }
  57   .rela.bss      : { *(.rela.bss)               }
  58   .rel.plt       : { *(.rel.plt)                }
  59   .rela.plt      : { *(.rela.plt)               }
  60   .init          : { *(.init)   }
  61   .plt : { *(.plt) }
  62   .text      :
  63   {
  64     /* WARNING - the following is hand-optimized to fit within  */
  65     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  66
  67     arch/powerpc/cpu/mpc8xx/start.o                     (.text)
  68     common/dlmalloc.o                   (.text)
  69     arch/powerpc/lib/ppcstring.o                        (.text)
  70     lib/vsprintf.o              (.text)
  71     lib/crc32.o                 (.text)
  72     lib/zlib.o                  (.text)
  73     lib/string.o                (.text)
  74     arch/powerpc/lib/cache.o                    (.text)
  75     arch/powerpc/lib/extable.o                  (.text)
  76     arch/powerpc/lib/time.o                     (.text)
  77     arch/powerpc/lib/ticks.o                    (.text)
  78
  79     . = env_offset;
  80     common/env_embedded.o               (.text)
  81
  82     *(.text)
  83     *(.got1)
  84   }
  85   _etext = .;
  86   PROVIDE (etext = .);
  87   .rodata    :
  88   {
  89     *(.eh_frame)
  90     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  91   }
  92   .fini      : { *(.fini)    } =0
  93   .ctors     : { *(.ctors)   }
  94   .dtors     : { *(.dtors)   }
  95
  96   /* Read-write section, merged into data segment: */
  97   . = (. + 0x00FF) & 0xFFFFFF00;
  98   _erotext = .;
  99   PROVIDE (erotext = .);
 100   .reloc   :
 101   {
 102     *(.got)
 103     _GOT2_TABLE_ = .;
 104     *(.got2)
 105     _FIXUP_TABLE_ = .;
 106     *(.fixup)
 107   }
 108   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 109   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 110
 111   .data    :
 112   {
 113     *(.data)
 114     *(.data1)
 115     *(.sdata)
 116     *(.sdata2)
 117     *(.dynamic)
 118     CONSTRUCTORS
 119   }
 120   _edata  =  .;
 121   PROVIDE (edata = .);
 122
 123   . = .;
 124   __u_boot_cmd_start = .;
 125   .u_boot_cmd : { *(.u_boot_cmd) }
 126   __u_boot_cmd_end = .;
 127
 128   . = .;
 129   __start___ex_table = .;
 130   __ex_table : { *(__ex_table) }
 131   __stop___ex_table = .;
 132
 133   . = ALIGN(256);
 134   __init_begin = .;
 135   .text.init : { *(.text.init) }
 136   .data.init : { *(.data.init) }
 137   . = ALIGN(256);
 138   __init_end = .;
 139
 140   __bss_start = .;
 141   .bss (NOLOAD)       :
 142   {
 143    *(.sbss) *(.scommon)
 144    *(.dynbss)
 145    *(.bss)
 146    *(COMMON)
 147    . = ALIGN(4);
 148   }
 149   _end = . ;
 150   PROVIDE (end = .);
 151 }