board/eNET/u-boot.lds

   1 /*
   2  * (C) Copyright 2002
   3  * Daniel Engström, Omicron Ceti AB, daniel@omicron.se.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  25 OUTPUT_ARCH(i386)
  26 ENTRY(_start)
  27
  28 SECTIONS
  29 {
  30         . = TEXT_BASE;          /* Location of bootcode in flash */
  31         __text_start = .;
  32         .text  : { *(.text*); }
  33
  34         . = ALIGN(4);
  35         __u_boot_cmd_start = .;
  36         .u_boot_cmd : { *(.u_boot_cmd) }
  37         . = ALIGN(4);
  38         __u_boot_cmd_end = .;
  39
  40         . = ALIGN(4);
  41         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  42
  43         . = ALIGN(4);
  44         .data : { *(.data*) }
  45
  46         . = ALIGN(4);
  47         .dynsym : { *(.dynsym*) }
  48
  49         . = ALIGN(4);
  50         .hash : { *(.hash*) }
  51
  52         . = ALIGN(4);
  53         .got : { *(.got*) }
  54
  55         . = ALIGN(4);
  56         __data_end = .;
  57
  58         . = ALIGN(4);
  59         __bss_start = ABSOLUTE(.);
  60         .bss (NOLOAD) : { *(.bss) }
  61         __bss_size = SIZEOF(.bss);
  62
  63         . = ALIGN(4);
  64         __rel_dyn_start = .;
  65         .rel.dyn : { *(.rel.dyn) }
  66         __rel_dyn_end = .;
  67
  68         /DISCARD/ : { *(.dynstr*) }
  69         /DISCARD/ : { *(.dynamic*) }
  70         /DISCARD/ : { *(.plt*) }
  71         /DISCARD/ : { *(.interp*) }
  72         /DISCARD/ : { *(.gnu*) }
  73
  74         /* 16bit realmode trampoline code */
  75         .realmode 0x7c0 : AT ( LOADADDR(.rel.dyn) + SIZEOF(.rel.dyn) ) { KEEP(*(.realmode)) }
  76
  77         __realmode_start = LOADADDR(.realmode);
  78         __realmode_size = SIZEOF(.realmode);
  79
  80         /* 16bit BIOS emulation code (just enough to boot Linux) */
  81         .bios 0 : AT ( LOADADDR(.realmode) + SIZEOF(.realmode) ) { KEEP(*(.bios)) }
  82
  83         __bios_start = LOADADDR(.bios);
  84         __bios_size = SIZEOF(.bios);
  85
  86         /* The load addresses below assumes that the flash
  87          * will be mapped so that 0x387f0000 == 0xffff0000
  88          * at reset time
  89          *
  90          * The fe00 and ff00 offsets of the start32 and start16
  91          * segments are arbitrary, the just have to be mapped
  92          * at reset and the code have to fit.
  93          * The fff0 offset of resetvec is important, however.
  94          */
  95         . = 0xfffffe00;
  96         .start32 : AT (TEXT_BASE + 0x3fe00) { KEEP(*(.start32)); }
  97
  98         . = 0xf800;
  99         .start16 : AT (TEXT_BASE + 0x3f800) { KEEP(*(.start16)); }
 100
 101         . = 0xfff0;
 102         .resetvec : AT (TEXT_BASE + 0x3fff0) { KEEP(*(.resetvec)); }
 103 }