board/earthlcd/favr-32-ezkit/u-boot.lds

   1 /* -*- Fundamental -*-
   2  *
   3  * Copyright (C) 2008 Atmel Corporation
   4  *
   5  * See file CREDITS for list of people who contributed to this project.
   6  *
   7  * This program is free software; you can redistribute it and/or modify it
   8  * under the terms of the GNU General Public License as published by the Free
   9  * Software Foundation; either version 2 of the License, or (at your option)
  10  * any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful, but WITHOUT
  13  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
  15  * more details.
  16  *
  17  * You should have received a copy of the GNU General Public License along with
  18  * this program; if not, write to the Free Software Foundation, Inc., 59 Temple
  19  * Place, Suite 330, Boston, MA 02111-1307 USA
  20  */
  21 OUTPUT_FORMAT("elf32-avr32", "elf32-avr32", "elf32-avr32")
  22 OUTPUT_ARCH(avr32)
  23 ENTRY(_start)
  24
  25 SECTIONS
  26 {
  27         . = 0;
  28         _text = .;
  29         .text : {
  30                 *(.exception.text)
  31                 *(.text)
  32                 *(.text.*)
  33         }
  34         _etext = .;
  35
  36         .rodata : {
  37                 *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  38         }
  39
  40         . = ALIGN(8);
  41         _data = .;
  42         .data : {
  43                 *(.data)
  44                 *(.data.*)
  45         }
  46
  47         . = ALIGN(4);
  48         __u_boot_cmd_start = .;
  49         .u_boot_cmd : {
  50                 KEEP(*(.u_boot_cmd))
  51         }
  52         __u_boot_cmd_end = .;
  53
  54         . = ALIGN(4);
  55         _got = .;
  56         .got : {
  57                 *(.got)
  58         }
  59         _egot = .;
  60
  61         . = ALIGN(8);
  62         _edata = .;
  63
  64         .bss (NOLOAD) : {
  65                 *(.bss)
  66                 *(.bss.*)
  67         }
  68         . = ALIGN(8);
  69         __bss_end__ = .;
  70 }