board/esd/dasa_sim/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25
  26 SECTIONS
  27 {
  28   .resetvec 0xFFFFFFFC :
  29   {
  30     KEEP(*(.resetvec))
  31   } = 0xffff
  32
  33   /* Read-only sections, merged into text segment: */
  34   . = + SIZEOF_HEADERS;
  35   .text      :
  36   {
  37     arch/powerpc/cpu/ppc4xx/start.o     (.text)
  38
  39     . = env_offset;
  40     common/env_embedded.o               (.text*)
  41
  42     *(.text*)
  43   }
  44   _etext = .;
  45   PROVIDE (etext = .);
  46   .rodata    :
  47   {
  48     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  49   }
  50
  51   /* Read-write section, merged into data segment: */
  52   . = (. + 0x0FFF) & 0xFFFFF000;
  53   _erotext = .;
  54   PROVIDE (erotext = .);
  55   .reloc   :
  56   {
  57     KEEP(*(.got))
  58     _GOT2_TABLE_ = .;
  59     KEEP(*(.got2))
  60     _FIXUP_TABLE_ = .;
  61     KEEP(*(.fixup))
  62   }
  63   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  64   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  65
  66   .data    :
  67   {
  68     *(.data*)
  69     *(.sdata*)
  70   }
  71   _edata  =  .;
  72   PROVIDE (edata = .);
  73
  74   . = .;
  75   __u_boot_cmd_start = .;
  76   .u_boot_cmd : { *(.u_boot_cmd) }
  77   __u_boot_cmd_end = .;
  78
  79
  80   . = .;
  81   __start___ex_table = .;
  82   __ex_table : { *(__ex_table) }
  83   __stop___ex_table = .;
  84
  85   . = ALIGN(4096);
  86   __init_begin = .;
  87   .text.init : { *(.text.init) }
  88   .data.init : { *(.data.init) }
  89   . = ALIGN(4096);
  90   __init_end = .;
  91
  92   __bss_start = .;
  93   .bss (NOLOAD)       :
  94   {
  95    *(.bss*)
  96    *(.sbss*)
  97    *(COMMON)
  98    . = ALIGN(4);
  99   }
 100   _end = . ;
 101   PROVIDE (end = .);
 102 }