board/karo/tx53/u-boot.lds

   1 /*
   2  * (C) Copyright 2012  Lothar Waßmann <LW@KARO-electronics.de>
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  23 OUTPUT_ARCH(arm)
  24 ENTRY(_start)
  25 SECTIONS
  26 {
  27         . = 0x00000000;
  28         .text :
  29         {
  30                 *(.__image_copy_start)
  31                 *(.vectors)
  32                 CPUDIR/start.o (.text*)
  33                 . = 0x400;
  34                 KEEP(BOARDDIR/lowlevel_init.o (.text*))
  35                 *(.text*)
  36         }
  37
  38 #if defined(CONFIG_ARMV7_NONSEC) || defined(CONFIG_ARMV7_VIRT) || defined(CONFIG_ARMV7_PSCI)
  39
  40 #ifndef CONFIG_ARMV7_SECURE_BASE
  41 #define CONFIG_ARMV7_SECURE_BASE
  42 #endif
  43
  44         .__secure_start : {
  45                 . = ALIGN(0x1000);
  46                 *(.__secure_start)
  47         }
  48
  49         .secure_text CONFIG_ARMV7_SECURE_BASE :
  50                 AT(ADDR(.__secure_start) + SIZEOF(.__secure_start))
  51         {
  52                 *(._secure.text)
  53         }
  54
  55         . = LOADADDR(.__secure_start) +
  56                 SIZEOF(.__secure_start) +
  57                 SIZEOF(.secure_text);
  58
  59         __secure_end_lma = .;
  60         .__secure_end : AT(__secure_end_lma) {
  61                 *(.__secure_end)
  62                 LONG(0x1d1071c);        /* Must output something to reset LMA */
  63         }
  64 #endif
  65
  66         . = ALIGN(4);
  67         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  68
  69         . = ALIGN(4);
  70         .data : {
  71                 *(.data*)
  72         }
  73
  74         . = ALIGN(4);
  75         .u_boot_list : {
  76                 KEEP(*(SORT(.u_boot_list*)));
  77         }
  78
  79         . = ALIGN(4);
  80         .image_copy_end :
  81         {
  82                 *(.__image_copy_end)
  83         }
  84
  85         .rel_dyn_start :
  86         {
  87                 *(.__rel_dyn_start)
  88         }
  89
  90         .rel.dyn :
  91         {
  92                 *(.rel*)
  93         }
  94
  95         .rel_dyn_end :
  96         {
  97                 *(.__rel_dyn_end)
  98         }
  99
 100         /* Workaround for an apparent bug in i.MX53 ROM Code,
 101          * that skips loading the last block if it doesn't
 102          * end on a 4KiB boundary.
 103          */
 104
 105         . = ALIGN(4096);
 106         .uboot_img_end :
 107         {
 108                 *(.__uboot_img_end)
 109         }
 110
 111         _image_binary_end = .;
 112
 113 /*
 114  * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
 115  * __bss_base and __bss_limit are for linker only (overlay ordering)
 116  */
 117
 118         .bss_start __rel_dyn_start (OVERLAY) : {
 119                 KEEP(*(.__bss_start));
 120                 __bss_base = .;
 121         }
 122
 123         .bss __bss_base (OVERLAY) : {
 124                 *(.bss*)
 125                 . = ALIGN(4);
 126                 __bss_limit = .;
 127         }
 128         .bss_end __bss_limit (OVERLAY) : {
 129                 KEEP(*(.__bss_end));
 130         }
 131
 132         .dynsym _image_binary_end : { *(.dynsym) }
 133         .dynbss : { *(.dynbss) }
 134         .dynstr : { *(.dynstr*) }
 135         .dynamic : { *(.dynamic*) }
 136         .plt : { *(.plt*) }
 137         .interp : { *(.interp*) }
 138         .gnu.hash : { *(.gnu.hash) }
 139         .gnu : { *(.gnu*) }
 140         .ARM.exidx : { *(.ARM.exidx*) }
 141         .gnu.linkonce.armexidx : { *(.gnu.linkonce.armexidx.*) }
 142 }