board/ppmc7xx/u-boot.lds

   1 /*
   2  * (C) Copyright 2001
   3  * Josh Huber <huber@mclx.com>, Mission Critical Linux, Inc.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 /*
  25  * u-boot.lds - linker script for U-Boot on the Galileo Eval Board.
  26  */
  27
  28 OUTPUT_ARCH(powerpc)
  29 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  30 /* Do we need any of these for elf?
  31    __DYNAMIC = 0;    */
  32 SECTIONS
  33 {
  34   /* Read-only sections, merged into text segment: */
  35   . = + SIZEOF_HEADERS;
  36   .interp : { *(.interp) }
  37   .hash          : { *(.hash)           }
  38   .dynsym        : { *(.dynsym)         }
  39   .dynstr        : { *(.dynstr)         }
  40   .rel.text      : { *(.rel.text)               }
  41   .rela.text     : { *(.rela.text)      }
  42   .rel.data      : { *(.rel.data)               }
  43   .rela.data     : { *(.rela.data)      }
  44   .rel.rodata    : { *(.rel.rodata)     }
  45   .rela.rodata   : { *(.rela.rodata)    }
  46   .rel.got       : { *(.rel.got)                }
  47   .rela.got      : { *(.rela.got)               }
  48   .rel.ctors     : { *(.rel.ctors)      }
  49   .rela.ctors    : { *(.rela.ctors)     }
  50   .rel.dtors     : { *(.rel.dtors)      }
  51   .rela.dtors    : { *(.rela.dtors)     }
  52   .rel.bss       : { *(.rel.bss)                }
  53   .rela.bss      : { *(.rela.bss)               }
  54   .rel.plt       : { *(.rel.plt)                }
  55   .rela.plt      : { *(.rela.plt)               }
  56   .init          : { *(.init)   }
  57   .plt : { *(.plt) }
  58   .text      :
  59   {
  60     cpu/74xx_7xx/start.o        (.text)
  61
  62 /* store the environment in a seperate sector in the boot flash */
  63 /*    . = env_offset; */
  64 /*    common/environment.o(.text) */
  65
  66     *(.text)
  67     *(.fixup)
  68     *(.got1)
  69   }
  70   _etext = .;
  71   PROVIDE (etext = .);
  72   .rodata    :
  73   {
  74     *(.rodata)
  75     *(.rodata1)
  76     *(.rodata.str1.4)
  77   }
  78   .fini      : { *(.fini)    } =0
  79   .ctors     : { *(.ctors)   }
  80   .dtors     : { *(.dtors)   }
  81
  82   /* Read-write section, merged into data segment: */
  83   . = (. + 0x00FF) & 0xFFFFFF00;
  84   _erotext = .;
  85   PROVIDE (erotext = .);
  86   .reloc   :
  87   {
  88     *(.got)
  89     _GOT2_TABLE_ = .;
  90     *(.got2)
  91     _FIXUP_TABLE_ = .;
  92     *(.fixup)
  93   }
  94   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  95   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  96
  97   .data    :
  98   {
  99     *(.data)
 100     *(.data1)
 101     *(.sdata)
 102     *(.sdata2)
 103     *(.dynamic)
 104     CONSTRUCTORS
 105   }
 106   _edata  =  .;
 107   PROVIDE (edata = .);
 108
 109   __u_boot_cmd_start = .;
 110   .u_boot_cmd : { *(.u_boot_cmd) }
 111   __u_boot_cmd_end = .;
 112
 113
 114   __start___ex_table = .;
 115   __ex_table : { *(__ex_table) }
 116   __stop___ex_table = .;
 117
 118   . = ALIGN(256);
 119   __init_begin = .;
 120   .text.init : { *(.text.init) }
 121   .data.init : { *(.data.init) }
 122   . = ALIGN(256);
 123   __init_end = .;
 124
 125   __bss_start = .;
 126   .bss       :
 127   {
 128    *(.sbss) *(.scommon)
 129    *(.dynbss)
 130    *(.bss)
 131    *(COMMON)
 132   }
 133   _end = . ;
 134   PROVIDE (end = .);
 135 }