board/r360mpi/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9
  10 SECTIONS
  11 {
  12   /* Read-only sections, merged into text segment: */
  13   . = + SIZEOF_HEADERS;
  14   .text      :
  15   {
  16     /* WARNING - the following is hand-optimized to fit within  */
  17     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  18     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  19     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  20
  21     *(.text*)
  22   }
  23   _etext = .;
  24   PROVIDE (etext = .);
  25   .rodata    :
  26   {
  27     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  28   }
  29
  30   /* Read-write section, merged into data segment: */
  31   . = (. + 0x00FF) & 0xFFFFFF00;
  32   _erotext = .;
  33   PROVIDE (erotext = .);
  34   .reloc   :
  35   {
  36     _GOT2_TABLE_ = .;
  37     KEEP(*(.got2))
  38     KEEP(*(.got))
  39     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  40     _FIXUP_TABLE_ = .;
  41     KEEP(*(.fixup))
  42   }
  43   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  44   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  45
  46   .data    :
  47   {
  48     *(.data*)
  49     *(.sdata*)
  50   }
  51   _edata  =  .;
  52   PROVIDE (edata = .);
  53
  54   . = .;
  55
  56   . = ALIGN(4);
  57   .u_boot_list : {
  58         KEEP(*(SORT(.u_boot_list*)));
  59   }
  60
  61
  62   . = .;
  63   __start___ex_table = .;
  64   __ex_table : { *(__ex_table) }
  65   __stop___ex_table = .;
  66
  67   . = ALIGN(256);
  68   __init_begin = .;
  69   .text.init : { *(.text.init) }
  70   .data.init : { *(.data.init) }
  71   . = ALIGN(256);
  72   __init_end = .;
  73
  74   __bss_start = .;
  75   .bss (NOLOAD)       :
  76   {
  77    *(.bss*)
  78    *(.sbss*)
  79    *(COMMON)
  80    . = ALIGN(4);
  81   }
  82   __bss_end = . ;
  83   PROVIDE (end = .);
  84   . = ALIGN(128 * 1024);
  85   .ppcenv       :
  86   {
  87     common/env_embedded.o (.ppcenv)
  88   }
  89 }