cpu/leon2/start.S

   1 /* This is where the SPARC/LEON3 starts
   2  * Copyright (C) 2007,
   3  * Daniel Hellstrom, daniel@gaisler.com
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 #include <config.h>
  25 #include <asm/asmmacro.h>
  26 #include <asm/winmacro.h>
  27 #include <asm/psr.h>
  28 #include <asm/stack.h>
  29 #include <asm/leon.h>
  30 #include <version.h>
  31
  32 /* Entry for traps which jump to a programmer-specified trap handler.  */
  33 #define TRAPR(H)  \
  34         wr      %g0, 0xfe0, %psr; \
  35         mov     %g0, %tbr; \
  36         ba      (H); \
  37         mov     %g0, %wim;
  38
  39 #define TRAP(H) \
  40         mov     %psr, %l0; \
  41         ba      (H); \
  42         nop; nop;
  43
  44 #define TRAPI(ilevel) \
  45         mov     ilevel, %l7; \
  46         mov     %psr, %l0; \
  47         b       _irq_entry; \
  48         mov     %wim, %l3
  49
  50 /* Unexcpected trap will halt the processor by forcing it to error state */
  51 #undef BAD_TRAP
  52 #define BAD_TRAP ta 0; nop; nop; nop;
  53
  54 /* Software trap. Treat as BAD_TRAP for the time being... */
  55 #define SOFT_TRAP TRAP(_hwerr)
  56
  57 #define PSR_INIT   0x1FC0       /* Disable traps, set s and ps */
  58 #define WIM_INIT   2
  59
  60 /* All traps low-level code here must end with this macro. */
  61 #define RESTORE_ALL b ret_trap_entry; clr %l6;
  62
  63 #define WRITE_PAUSE nop;nop;nop
  64
  65 WINDOWSIZE = (16 * 4)
  66 ARGPUSHSIZE = (6 * 4)
  67 ARGPUSH = (WINDOWSIZE + 4)
  68 MINFRAME = (WINDOWSIZE + ARGPUSHSIZE + 4)
  69
  70 /* Number of register windows */
  71 #ifndef CFG_SPARC_NWINDOWS
  72 #error Must define number of SPARC register windows, default is 8
  73 #endif
  74
  75 #define STACK_ALIGN     8
  76 #define SA(X)   (((X)+(STACK_ALIGN-1)) & ~(STACK_ALIGN-1))
  77
  78         .section ".start", "ax"
  79         .globl  _start, start, _trap_table
  80         .globl  _irq_entry, nmi_trap
  81         .globl  _reset_reloc
  82
  83 /* at address 0
  84  * Hardware traps
  85  */
  86 start:
  87 _start:
  88 _trap_table:
  89         TRAPR(_hardreset);              ! 00 reset trap
  90         BAD_TRAP;                       ! 01 instruction_access_exception
  91         BAD_TRAP;                       ! 02 illegal_instruction
  92         BAD_TRAP;                       ! 03 priveleged_instruction
  93         BAD_TRAP;                       ! 04 fp_disabled
  94         TRAP(_window_overflow);         ! 05 window_overflow
  95         TRAP(_window_underflow);        ! 06 window_underflow
  96         BAD_TRAP;                       ! 07 Memory Address Not Aligned
  97         BAD_TRAP;                       ! 08 Floating Point Exception
  98         BAD_TRAP;                       ! 09 Data Miss Exception
  99         BAD_TRAP;                       ! 0a Tagged Instruction Ovrflw
 100         BAD_TRAP;                       ! 0b Watchpoint Detected
 101         BAD_TRAP;                       ! 0c
 102         BAD_TRAP;                       ! 0d
 103         BAD_TRAP;                       ! 0e
 104         BAD_TRAP;                       ! 0f
 105         BAD_TRAP;                       ! 10
 106         TRAPI(1);                       ! 11 IRQ level 1
 107         TRAPI(2);                       ! 12 IRQ level 2
 108         TRAPI(3);                       ! 13 IRQ level 3
 109         TRAPI(4);                       ! 14 IRQ level 4
 110         TRAPI(5);                       ! 15 IRQ level 5
 111         TRAPI(6);                       ! 16 IRQ level 6
 112         TRAPI(7);                       ! 17 IRQ level 7
 113         TRAPI(8);                       ! 18 IRQ level 8
 114         TRAPI(9);                       ! 19 IRQ level 9
 115         TRAPI(10);                      ! 1a IRQ level 10
 116         TRAPI(11);                      ! 1b IRQ level 11
 117         TRAPI(12);                      ! 1c IRQ level 12
 118         TRAPI(13);                      ! 1d IRQ level 13
 119         TRAPI(14);                      ! 1e IRQ level 14
 120         TRAP(_nmi_trap);                ! 1f IRQ level 15 /
 121                                         ! NMI (non maskable interrupt)
 122         BAD_TRAP;                       ! 20 r_register_access_error
 123         BAD_TRAP;                       ! 21 instruction access error
 124         BAD_TRAP;                       ! 22
 125         BAD_TRAP;                       ! 23
 126         BAD_TRAP;                       ! 24 co-processor disabled
 127         BAD_TRAP;                       ! 25 uniplemented FLUSH
 128         BAD_TRAP;                       ! 26
 129         BAD_TRAP;                       ! 27
 130         BAD_TRAP;                       ! 28 co-processor exception
 131         BAD_TRAP;                       ! 29 data access error
 132         BAD_TRAP;                       ! 2a division by zero
 133         BAD_TRAP;                       ! 2b data store error
 134         BAD_TRAP;                       ! 2c data access MMU miss
 135         BAD_TRAP;                       ! 2d
 136         BAD_TRAP;                       ! 2e
 137         BAD_TRAP;                       ! 2f
 138         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 30-33
 139         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 34-37
 140         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 38-3b
 141         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 3c-3f
 142         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 40-43
 143         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 44-47
 144         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 48-4b
 145         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 4c-4f
 146         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 50-53
 147         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 54-57
 148         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 58-5b
 149         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 5c-5f
 150
 151         /* implementaion dependent */
 152         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 60-63
 153         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 64-67
 154         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 68-6b
 155         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 6c-6f
 156         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 70-73
 157         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 74-77
 158         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 78-7b
 159         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 7c-7f
 160
 161         /* Software traps, not handled */
 162         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 80-83
 163         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 84-87
 164         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 88-8b
 165         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 8c-8f
 166         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 90-93
 167         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 94-97
 168         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 98-9b
 169         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 9c-9f
 170         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! a0-a3
 171         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! a4-a7
 172         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! a8-ab
 173         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! ac-af
 174         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! b0-b3
 175         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! b4-b7
 176         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! b8-bb
 177         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! bc-bf
 178         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! c0-c3
 179         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! c4-c7
 180         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! c8-cb
 181         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! cc-cf
 182         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! d0-d3
 183         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! d4-d7
 184         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! d8-db
 185         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! dc-df
 186         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! e0-e3
 187         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! e4-e7
 188         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! e8-eb
 189         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! ec-ef
 190         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! f0-f3
 191         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! f4-f7
 192         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! f8-fb
 193         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! fc-ff
 194 /*
 195  * Version string
 196  */
 197
 198         .data
 199         .globl  version_string
 200 version_string:
 201         .ascii U_BOOT_VERSION
 202         .ascii " (", __DATE__, " - ", __TIME__, ")"
 203         .ascii CONFIG_IDENT_STRING, "\0"
 204
 205         .section        ".text"
 206         .align 4
 207
 208 _hardreset:
 209 1000:
 210         flush
 211         nop
 212         nop
 213         nop
 214
 215         /* Init Cache */
 216         set     (LEON2_PREGS+LEON_REG_CACHECTRL_OFFSET), %g1
 217         set     0x0081000f, %g2
 218         st      %g2, [%g1]
 219
 220         mov     %g0, %y
 221         clr     %g1
 222         clr     %g2
 223         clr     %g3
 224         clr     %g4
 225         clr     %g5
 226         clr     %g6
 227         clr     %g7
 228
 229         mov     %asr17, %g3
 230         and     %g3, 0x1f, %g3
 231 clear_window:
 232         mov     %g0, %l0
 233         mov     %g0, %l1
 234         mov     %g0, %l2
 235         mov     %g0, %l3
 236         mov     %g0, %l4
 237         mov     %g0, %l5
 238         mov     %g0, %l6
 239         mov     %g0, %l7
 240         mov     %g0, %o0
 241         mov     %g0, %o1
 242         mov     %g0, %o2
 243         mov     %g0, %o3
 244         mov     %g0, %o4
 245         mov     %g0, %o5
 246         mov     %g0, %o6
 247         mov     %g0, %o7
 248         subcc   %g3, 1, %g3
 249         bge     clear_window
 250         save
 251
 252 leon2_init:
 253         /* LEON2 Register Base in g1 */
 254         set     LEON2_PREGS, %g1
 255
 256 leon2_init_cache:
 257         /* Set Cache control register */
 258         set     0x1000f, %g2
 259         st      %g2, [%g1 + 0x14]
 260
 261 leon2_init_clear:
 262
 263         /* Clear LEON2 registers */
 264         st      %g0, [%g1 + LEON2_ECTRL]
 265         st      %g0, [%g1 + LEON2_IMASK]
 266         st      %g0, [%g1 + LEON2_IPEND]
 267         st      %g0, [%g1 + LEON2_IFORCE]
 268         st      %g0, [%g1 + LEON2_ICLEAR]
 269         st      %g0, [%g1 + LEON2_IOREG]
 270         st      %g0, [%g1 + LEON2_IODIR]
 271         st      %g0, [%g1 + LEON2_IOICONF]
 272         st      %g0, [%g1 + LEON2_UCTRL0]
 273         st      %g0, [%g1 + LEON2_UCTRL1]
 274
 275 leon2_init_ioport:
 276         /* I/O port initialization */
 277         set     0xaa00, %g2
 278         st      %g2, [%g1 + LEON2_IOREG]
 279
 280 leon2_init_mctrl:
 281
 282         /* memory config register 1 */
 283         set     CFG_GRLIB_MEMCFG1, %g2
 284         ld      [%g1], %g3              !
 285         and     %g3, 0x300, %g3
 286         or      %g2, %g3, %g2
 287         st      %g2, [%g1 + LEON2_MCFG1]
 288         set     CFG_GRLIB_MEMCFG2, %g2          ! Load memory config register 2
 289 #if !( defined(TSIM) || !defined(BZIMAGE))
 290         st      %g2, [%g1 + LEON2_MCFG2]        ! only for prom version, else done by "dumon -i"
 291 #endif
 292         set     CFG_GRLIB_MEMCFG3, %g2          ! Init FT register
 293         st      %g2, [%g1 + LEON2_ECTRL]
 294         ld      [%g1 + LEON2_ECTRL], %g2
 295         srl     %g2, 30, %g2
 296         andcc   %g2, 3, %g6
 297         bne,a   leon2_init_wim
 298         mov     %g0, %asr16             ! clear err_reg
 299
 300 leon2_init_wim:
 301         set     WIM_INIT, %g3
 302         mov     %g3, %wim
 303
 304 leon2_init_psr:
 305         set     0x1000, %g3
 306         mov     %psr, %g2
 307         wr      %g2, %g3, %psr
 308         nop
 309         nop
 310         nop
 311
 312 leon2_init_stackp:
 313         set     CFG_INIT_SP_OFFSET, %fp
 314         andn    %fp, 0x0f, %fp
 315         sub     %fp, 64, %sp
 316
 317 cpu_init_unreloc:
 318         call    cpu_init_f
 319         nop
 320
 321 /* un relocated start address of monitor */
 322 #define TEXT_START _text
 323
 324 /* un relocated end address of monitor */
 325 #define DATA_END __init_end
 326
 327 reloc:
 328         set     TEXT_START,%g2
 329         set     DATA_END,%g3
 330         set     CFG_RELOC_MONITOR_BASE,%g4
 331 reloc_loop:
 332         ldd     [%g2],%l0
 333         ldd     [%g2+8],%l2
 334         std     %l0,[%g4]
 335         std     %l2,[%g4+8]
 336         inc     16,%g2
 337         subcc   %g3,%g2,%g0
 338         bne     reloc_loop
 339         inc     16,%g4
 340
 341         clr     %l0
 342         clr     %l1
 343         clr     %l2
 344         clr     %l3
 345         clr     %g2
 346
 347 /* register g4 contain address to start
 348  * This means that BSS must be directly after data and code segments
 349  *
 350  * g3 is length of bss = (__bss_end-__bss_start)
 351  *
 352  */
 353
 354 clr_bss:
 355 /* clear bss area (the relocated) */
 356         set     __bss_start,%g2
 357         set     __bss_end,%g3
 358         sub     %g3,%g2,%g3
 359         add     %g3,%g4,%g3
 360         clr     %g1     /* std %g0 uses g0 and g1 */
 361 /* clearing 16byte a time ==> linker script need to align to 16 byte offset */
 362 clr_bss_16:
 363         std     %g0,[%g4]
 364         std     %g0,[%g4+8]
 365         inc     16,%g4
 366         cmp     %g3,%g4
 367         bne     clr_bss_16
 368         nop
 369
 370 /* add offsets to GOT table */
 371 fixup_got:
 372         set     __got_start,%g4
 373         set     __got_end,%g3
 374 /*
 375  * new got offset = (old GOT-PTR (read with ld) -
 376  *   CFG_RELOC_MONITOR_BASE(from define) ) +
 377  *   Destination Address (from define)
 378  */
 379         set     CFG_RELOC_MONITOR_BASE,%g2
 380         set     TEXT_START, %g1
 381         add     %g4,%g2,%g4
 382         sub     %g4,%g1,%g4
 383         add     %g3,%g2,%g3
 384         sub     %g3,%g1,%g3
 385         sub     %g2,%g1,%g2     ! prepare register with (new base address) -
 386                                 !  (old base address)
 387 got_loop:
 388         ld      [%g4],%l0       ! load old GOT-PTR
 389         add     %l0,%g2,%l0     ! increase with (new base address) -
 390                                 !  (old base)
 391         st      %l0,[%g4]
 392         inc     4,%g4
 393         cmp     %g3,%g4
 394         bne     got_loop
 395         nop
 396
 397 prom_relocate:
 398         set     __prom_start, %g2
 399         set     __prom_end, %g3
 400         set     CFG_PROM_OFFSET, %g4
 401
 402 prom_relocate_loop:
 403         ldd     [%g2],%l0
 404         ldd     [%g2+8],%l2
 405         std     %l0,[%g4]
 406         std     %l2,[%g4+8]
 407         inc     16,%g2
 408         subcc   %g3,%g2,%g0
 409         bne     prom_relocate_loop
 410         inc     16,%g4
 411
 412 /* Trap table has been moved, lets tell CPU about
 413  * the new trap table address
 414  */
 415
 416         set     CFG_RELOC_MONITOR_BASE, %g2
 417         wr      %g0, %g2, %tbr
 418
 419 /*      call    relocate*/
 420         nop
 421 /* Call relocated init functions */
 422 jump:
 423         set     cpu_init_f2,%o1
 424         set     CFG_RELOC_MONITOR_BASE,%o2
 425         add     %o1,%o2,%o1
 426         sub     %o1,%g1,%o1
 427         call    %o1
 428         clr     %o0
 429
 430         set     board_init_f,%o1
 431         set     CFG_RELOC_MONITOR_BASE,%o2
 432         add     %o1,%o2,%o1
 433         sub     %o1,%g1,%o1
 434         call    %o1
 435         clr     %o0
 436
 437 dead:   ta 0                            ! if call returns...
 438         nop
 439
 440 /* Interrupt handler caller,
 441  * reg L7: interrupt number
 442  * reg L0: psr after interrupt
 443  * reg L1: PC
 444  * reg L2: next PC
 445  * reg L3: wim
 446  */
 447 _irq_entry:
 448         SAVE_ALL
 449
 450         or      %l0, PSR_PIL, %g2
 451         wr      %g2, 0x0, %psr
 452         WRITE_PAUSE
 453         wr      %g2, PSR_ET, %psr
 454         WRITE_PAUSE
 455         mov     %l7, %o0                ! irq level
 456         set     handler_irq, %o1
 457         set     (CFG_RELOC_MONITOR_BASE-TEXT_BASE), %o2
 458         add     %o1, %o2, %o1
 459         call    %o1
 460         add     %sp, SF_REGS_SZ, %o1    ! pt_regs ptr
 461         or      %l0, PSR_PIL, %g2       ! restore PIL after handler_irq
 462         wr      %g2, PSR_ET, %psr       ! keep ET up
 463         WRITE_PAUSE
 464
 465         RESTORE_ALL
 466
 467 !Window overflow trap handler.
 468         .global _window_overflow
 469
 470 _window_overflow:
 471
 472         mov     %wim, %l3               ! Calculate next WIM
 473         mov     %g1, %l7
 474         srl     %l3, 1, %g1
 475         sll     %l3, (CFG_SPARC_NWINDOWS-1) , %l4
 476         or      %l4, %g1, %g1
 477
 478         save                            ! Get into window to be saved.
 479         mov     %g1, %wim
 480         nop;
 481         nop;
 482         nop
 483         st      %l0, [%sp + 0];
 484         st      %l1, [%sp + 4];
 485         st      %l2, [%sp + 8];
 486         st      %l3, [%sp + 12];
 487         st      %l4, [%sp + 16];
 488         st      %l5, [%sp + 20];
 489         st      %l6, [%sp + 24];
 490         st      %l7, [%sp + 28];
 491         st      %i0, [%sp + 32];
 492         st      %i1, [%sp + 36];
 493         st      %i2, [%sp + 40];
 494         st      %i3, [%sp + 44];
 495         st      %i4, [%sp + 48];
 496         st      %i5, [%sp + 52];
 497         st      %i6, [%sp + 56];
 498         st      %i7, [%sp + 60];
 499         restore                         ! Go back to trap window.
 500         mov     %l7, %g1
 501         jmp     %l1                     ! Re-execute save.
 502         rett    %l2
 503
 504 /* Window underflow trap handler.  */
 505
 506         .global  _window_underflow
 507
 508 _window_underflow:
 509
 510         mov  %wim, %l3                  ! Calculate next WIM
 511         sll  %l3, 1, %l4
 512         srl  %l3, (CFG_SPARC_NWINDOWS-1), %l5
 513         or   %l5, %l4, %l5
 514         mov  %l5, %wim
 515         nop; nop; nop
 516         restore                         ! Two restores to get into the
 517         restore                         ! window to restore
 518         ld      [%sp + 0], %l0;         ! Restore window from the stack
 519         ld      [%sp + 4], %l1;
 520         ld      [%sp + 8], %l2;
 521         ld      [%sp + 12], %l3;
 522         ld      [%sp + 16], %l4;
 523         ld      [%sp + 20], %l5;
 524         ld      [%sp + 24], %l6;
 525         ld      [%sp + 28], %l7;
 526         ld      [%sp + 32], %i0;
 527         ld      [%sp + 36], %i1;
 528         ld      [%sp + 40], %i2;
 529         ld      [%sp + 44], %i3;
 530         ld      [%sp + 48], %i4;
 531         ld      [%sp + 52], %i5;
 532         ld      [%sp + 56], %i6;
 533         ld      [%sp + 60], %i7;
 534         save                            ! Get back to the trap window.
 535         save
 536         jmp     %l1                     ! Re-execute restore.
 537         rett    %l2
 538
 539         retl
 540
 541 _nmi_trap:
 542         nop
 543         jmp %l1
 544         rett %l2
 545
 546 _hwerr:
 547         ta 0
 548         nop
 549         nop
 550         b _hwerr                        ! loop infinite
 551         nop
 552
 553 /* Registers to not touch at all. */
 554 #define t_psr      l0 /* Set by caller */
 555 #define t_pc       l1 /* Set by caller */
 556 #define t_npc      l2 /* Set by caller */
 557 #define t_wim      l3 /* Set by caller */
 558 #define t_twinmask l4 /* Set at beginning of this entry routine. */
 559 #define t_kstack   l5 /* Set right before pt_regs frame is built */
 560 #define t_retpc    l6 /* If you change this, change winmacro.h header file */
 561 #define t_systable l7 /* Never touch this, could be the syscall table ptr. */
 562 #define curptr     g6 /* Set after pt_regs frame is built */
 563
 564 trap_setup:
 565 /* build a pt_regs trap frame. */
 566         sub     %fp, (SF_REGS_SZ + PT_REGS_SZ), %t_kstack
 567         PT_STORE_ALL(t_kstack, t_psr, t_pc, t_npc, g2)
 568
 569         /* See if we are in the trap window. */
 570         mov     1, %t_twinmask
 571         sll     %t_twinmask, %t_psr, %t_twinmask ! t_twinmask = (1 << psr)
 572         andcc   %t_twinmask, %t_wim, %g0
 573         beq     1f              ! in trap window, clean up
 574         nop
 575
 576         /*-------------------------------------------------
 577          * Spill , adjust %wim and go.
 578          */
 579         srl     %t_wim, 0x1, %g2                ! begin computation of new %wim
 580
 581         set     (CFG_SPARC_NWINDOWS-1), %g3     !NWINDOWS-1
 582
 583         sll     %t_wim, %g3, %t_wim     ! NWINDOWS-1
 584         or      %t_wim, %g2, %g2
 585         and     %g2, 0xff, %g2
 586
 587         save    %g0, %g0, %g0           ! get in window to be saved
 588
 589         /* Set new %wim value */
 590         wr      %g2, 0x0, %wim
 591
 592         /* Save the kernel window onto the corresponding stack. */
 593         RW_STORE(sp)
 594
 595         restore %g0, %g0, %g0
 596         /*-------------------------------------------------*/
 597
 598 1:
 599         /* Trap from kernel with a window available.
 600          * Just do it...
 601          */
 602         jmpl    %t_retpc + 0x8, %g0     ! return to caller
 603          mov    %t_kstack, %sp          ! jump onto new stack
 604
 605 #define twin_tmp1 l4
 606 #define glob_tmp  g4
 607 #define curptr    g6
 608 ret_trap_entry:
 609         wr      %t_psr, 0x0, %psr       ! enable nesting again, clear ET
 610
 611         /* Will the rett land us in the invalid window? */
 612         mov     2, %g1
 613         sll     %g1, %t_psr, %g1
 614
 615         set     CFG_SPARC_NWINDOWS, %g2 !NWINDOWS
 616
 617         srl     %g1, %g2, %g2
 618         or      %g1, %g2, %g1
 619         rd      %wim, %g2
 620         andcc   %g2, %g1, %g0
 621         be      1f              ! Nope, just return from the trap
 622          sll    %g2, 0x1, %g1
 623
 624         /* We have to grab a window before returning. */
 625         set     (CFG_SPARC_NWINDOWS-1), %g3     !NWINDOWS-1
 626
 627         srl     %g2, %g3,  %g2
 628         or      %g1, %g2, %g1
 629         and     %g1, 0xff, %g1
 630
 631         wr      %g1, 0x0, %wim
 632
 633         /* Grrr, make sure we load from the right %sp... */
 634         PT_LOAD_ALL(sp, t_psr, t_pc, t_npc, g1)
 635
 636         restore %g0, %g0, %g0
 637         RW_LOAD(sp)
 638         b       2f
 639         save    %g0, %g0, %g0
 640
 641         /* Reload the entire frame in case this is from a
 642          * kernel system call or whatever...
 643          */
 644 1:
 645         PT_LOAD_ALL(sp, t_psr, t_pc, t_npc, g1)
 646 2:
 647         wr      %t_psr, 0x0, %psr
 648         nop;
 649         nop;
 650         nop
 651
 652         jmp     %t_pc
 653         rett    %t_npc
 654
 655 /* This is called from relocated C-code.
 656  * It resets the system by jumping to _start
 657  */
 658 _reset_reloc:
 659         set     start, %l0
 660         call    %l0
 661         nop