cpu/mpc85xx/u-boot.lds

   1 /*
   2  * Copyright 2007-2009 Freescale Semiconductor, Inc.
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22
  23 #ifndef RESET_VECTOR_ADDRESS
  24 #define RESET_VECTOR_ADDRESS    0xfffffffc
  25 #endif
  26
  27 OUTPUT_ARCH(powerpc)
  28 /* Do we need any of these for elf?
  29    __DYNAMIC = 0;    */
  30 PHDRS
  31 {
  32   text PT_LOAD;
  33   bss PT_LOAD;
  34 }
  35
  36 SECTIONS
  37 {
  38   /* Read-only sections, merged into text segment: */
  39   . = + SIZEOF_HEADERS;
  40   .interp : { *(.interp) }
  41   .hash          : { *(.hash)           }
  42   .dynsym        : { *(.dynsym)         }
  43   .dynstr        : { *(.dynstr)         }
  44   .rel.text      : { *(.rel.text)               }
  45   .rela.text     : { *(.rela.text)      }
  46   .rel.data      : { *(.rel.data)               }
  47   .rela.data     : { *(.rela.data)      }
  48   .rel.rodata    : { *(.rel.rodata)     }
  49   .rela.rodata   : { *(.rela.rodata)    }
  50   .rel.got       : { *(.rel.got)                }
  51   .rela.got      : { *(.rela.got)               }
  52   .rel.ctors     : { *(.rel.ctors)      }
  53   .rela.ctors    : { *(.rela.ctors)     }
  54   .rel.dtors     : { *(.rel.dtors)      }
  55   .rela.dtors    : { *(.rela.dtors)     }
  56   .rel.bss       : { *(.rel.bss)                }
  57   .rela.bss      : { *(.rela.bss)               }
  58   .rel.plt       : { *(.rel.plt)                }
  59   .rela.plt      : { *(.rela.plt)               }
  60   .init          : { *(.init)   }
  61   .plt : { *(.plt) }
  62   .text      :
  63   {
  64     *(.text)
  65     *(.fixup)
  66     *(.got1)
  67    } :text
  68     _etext = .;
  69     PROVIDE (etext = .);
  70     .rodata    :
  71    {
  72     *(.eh_frame)
  73     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  74   } :text
  75   .fini      : { *(.fini)    } =0
  76   .ctors     : { *(.ctors)   }
  77   .dtors     : { *(.dtors)   }
  78
  79   /* Read-write section, merged into data segment: */
  80   . = (. + 0x00FF) & 0xFFFFFF00;
  81   _erotext = .;
  82   PROVIDE (erotext = .);
  83   .reloc   :
  84   {
  85     *(.got)
  86     _GOT2_TABLE_ = .;
  87     *(.got2)
  88     _FIXUP_TABLE_ = .;
  89     *(.fixup)
  90   }
  91   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  92   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  93
  94   .data    :
  95   {
  96     *(.data)
  97     *(.data1)
  98     *(.sdata)
  99     *(.sdata2)
 100     *(.dynamic)
 101     CONSTRUCTORS
 102   }
 103   _edata  =  .;
 104   PROVIDE (edata = .);
 105
 106   . = .;
 107   __u_boot_cmd_start = .;
 108   .u_boot_cmd : { *(.u_boot_cmd) }
 109   __u_boot_cmd_end = .;
 110
 111   . = .;
 112   __start___ex_table = .;
 113   __ex_table : { *(__ex_table) }
 114   __stop___ex_table = .;
 115
 116   . = ALIGN(256);
 117   __init_begin = .;
 118   .text.init : { *(.text.init) }
 119   .data.init : { *(.data.init) }
 120   . = ALIGN(256);
 121   __init_end = .;
 122
 123   .bootpg RESET_VECTOR_ADDRESS - 0xffc :
 124   {
 125     cpu/mpc85xx/start.o (.bootpg)
 126   } :text = 0xffff
 127
 128   .resetvec RESET_VECTOR_ADDRESS :
 129   {
 130     *(.resetvec)
 131   } :text = 0xffff
 132
 133   . = RESET_VECTOR_ADDRESS + 0x4;
 134
 135   __bss_start = .;
 136   .bss (NOLOAD)       :
 137   {
 138    *(.sbss) *(.scommon)
 139    *(.dynbss)
 140    *(.bss)
 141    *(COMMON)
 142   } :bss
 143
 144   . = ALIGN(4);
 145   _end = . ;
 146   PROVIDE (end = .);
 147 }