arch/arm/cpu/armv7/start.S

   1 /*
   2  * armboot - Startup Code for OMAP3530/ARM Cortex CPU-core
   3  *
   4  * Copyright (c) 2004   Texas Instruments <r-woodruff2@ti.com>
   5  *
   6  * Copyright (c) 2001   Marius Gröger <mag@sysgo.de>
   7  * Copyright (c) 2002   Alex Züpke <azu@sysgo.de>
   8  * Copyright (c) 2002   Gary Jennejohn <garyj@denx.de>
   9  * Copyright (c) 2003   Richard Woodruff <r-woodruff2@ti.com>
  10  * Copyright (c) 2003   Kshitij <kshitij@ti.com>
  11  * Copyright (c) 2006-2008 Syed Mohammed Khasim <x0khasim@ti.com>
  12  *
  13  * See file CREDITS for list of people who contributed to this
  14  * project.
  15  *
  16  * This program is free software; you can redistribute it and/or
  17  * modify it under the terms of the GNU General Public License as
  18  * published by the Free Software Foundation; either version 2 of
  19  * the License, or (at your option) any later version.
  20  *
  21  * This program is distributed in the hope that it will be useful,
  22  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  23  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24  * GNU General Public License for more details.
  25  *
  26  * You should have received a copy of the GNU General Public License
  27  * along with this program; if not, write to the Free Software
  28  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  29  * MA 02111-1307 USA
  30  */
  31
  32 #include <asm-offsets.h>
  33 #include <config.h>
  34 #include <version.h>
  35 #include <asm/system.h>
  36
  37 .globl _start
  38 _start: b       reset
  39         ldr     pc, _undefined_instruction
  40         ldr     pc, _software_interrupt
  41         ldr     pc, _prefetch_abort
  42         ldr     pc, _data_abort
  43         ldr     pc, _not_used
  44         ldr     pc, _irq
  45         ldr     pc, _fiq
  46 #ifdef CONFIG_SPL_BUILD
  47 _undefined_instruction: .word _undefined_instruction
  48 _software_interrupt:    .word _software_interrupt
  49 _prefetch_abort:        .word _prefetch_abort
  50 _data_abort:            .word _data_abort
  51 _not_used:              .word _not_used
  52 _irq:                   .word _irq
  53 _fiq:                   .word _fiq
  54 _pad:                   .word 0x12345678 /* now 16*4=64 */
  55 #else
  56 _undefined_instruction: .word undefined_instruction
  57 _software_interrupt:    .word software_interrupt
  58 _prefetch_abort:        .word prefetch_abort
  59 _data_abort:            .word data_abort
  60 _not_used:              .word not_used
  61 _irq:                   .word irq
  62 _fiq:                   .word fiq
  63 _pad:                   .word 0x12345678 /* now 16*4=64 */
  64 #endif  /* CONFIG_SPL_BUILD */
  65
  66 .global _end_vect
  67 _end_vect:
  68
  69         .balignl 16,0xdeadbeef
  70 /*************************************************************************
  71  *
  72  * Startup Code (reset vector)
  73  *
  74  * do important init only if we don't start from memory!
  75  * setup Memory and board specific bits prior to relocation.
  76  * relocate armboot to ram
  77  * setup stack
  78  *
  79  *************************************************************************/
  80
  81 .globl _TEXT_BASE
  82 _TEXT_BASE:
  83         .word   CONFIG_SYS_TEXT_BASE
  84
  85 /*
  86  * These are defined in the board-specific linker script.
  87  */
  88 .globl _bss_start_ofs
  89 _bss_start_ofs:
  90         .word __bss_start - _start
  91
  92 .global _image_copy_end_ofs
  93 _image_copy_end_ofs:
  94         .word   __image_copy_end - _start
  95
  96 .globl _bss_end_ofs
  97 _bss_end_ofs:
  98         .word __bss_end__ - _start
  99
 100 .globl _end_ofs
 101 _end_ofs:
 102         .word _end - _start
 103
 104 #ifdef CONFIG_USE_IRQ
 105 /* IRQ stack memory (calculated at run-time) */
 106 .globl IRQ_STACK_START
 107 IRQ_STACK_START:
 108         .word   0x0badc0de
 109
 110 /* IRQ stack memory (calculated at run-time) */
 111 .globl FIQ_STACK_START
 112 FIQ_STACK_START:
 113         .word 0x0badc0de
 114 #endif
 115
 116 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 117 .globl IRQ_STACK_START_IN
 118 IRQ_STACK_START_IN:
 119         .word   0x0badc0de
 120
 121 /*
 122  * the actual reset code
 123  */
 124
 125 reset:
 126         bl      save_boot_params
 127         /*
 128          * set the cpu to SVC32 mode
 129          */
 130         mrs     r0, cpsr
 131         bic     r0, r0, #0x1f
 132         orr     r0, r0, #0xd3
 133         msr     cpsr,r0
 134
 135 #if !defined(CONFIG_TEGRA2)
 136 /*
 137  * Setup vector:
 138  * (OMAP4 spl TEXT_BASE is not 32 byte aligned.
 139  * Continue to use ROM code vector only in OMAP4 spl)
 140  */
 141 #if !(defined(CONFIG_OMAP44XX) && defined(CONFIG_SPL_BUILD))
 142         /* Set V=0 in CP15 SCTRL register - for VBAR to point to vector */
 143         mrc     p15, 0, r0, c1, c0, 0   @ Read CP15 SCTRL Register
 144         bic     r0, #CR_V               @ V = 0
 145         mcr     p15, 0, r0, c1, c0, 0   @ Write CP15 SCTRL Register
 146
 147         /* Set vector address in CP15 VBAR register */
 148         ldr     r0, =_start
 149         mcr     p15, 0, r0, c12, c0, 0  @Set VBAR
 150 #endif
 151 #endif  /* !Tegra2 */
 152
 153         /* the mask ROM code should have PLL and others stable */
 154 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 155         bl      cpu_init_cp15
 156         bl      cpu_init_crit
 157 #endif
 158
 159 /* Set stackpointer in internal RAM to call board_init_f */
 160 call_board_init_f:
 161         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 162         bic     sp, sp, #7 /* 8-byte alignment for ABI compliance */
 163         ldr     r0,=0x00000000
 164         bl      board_init_f
 165
 166 /*------------------------------------------------------------------------------*/
 167
 168 /*
 169  * void relocate_code (addr_sp, gd, addr_moni)
 170  *
 171  * This "function" does not return, instead it continues in RAM
 172  * after relocating the monitor code.
 173  *
 174  */
 175         .globl  relocate_code
 176 relocate_code:
 177         mov     r4, r0  /* save addr_sp */
 178         mov     r5, r1  /* save addr of gd */
 179         mov     r6, r2  /* save addr of destination */
 180
 181         /* Set up the stack                                                 */
 182 stack_setup:
 183         mov     sp, r4
 184
 185         adr     r0, _start
 186         cmp     r0, r6
 187         moveq   r9, #0          /* no relocation. relocation offset(r9) = 0 */
 188         beq     clear_bss               /* skip relocation */
 189         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 190         ldr     r3, _image_copy_end_ofs
 191         add     r2, r0, r3              /* r2 <- source end address         */
 192
 193 copy_loop:
 194         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 195         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
 196         cmp     r0, r2                  /* until source end address [r2]    */
 197         blo     copy_loop
 198
 199 #ifndef CONFIG_SPL_BUILD
 200         /*
 201          * fix .rel.dyn relocations
 202          */
 203         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 204         sub     r9, r6, r0              /* r9 <- relocation offset */
 205         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 206         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 207         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 208         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 209         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 210         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 211 fixloop:
 212         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 213         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 214         ldr     r1, [r2, #4]
 215         and     r7, r1, #0xff
 216         cmp     r7, #23                 /* relative fixup? */
 217         beq     fixrel
 218         cmp     r7, #2                  /* absolute fixup? */
 219         beq     fixabs
 220         /* ignore unknown type of fixup */
 221         b       fixnext
 222 fixabs:
 223         /* absolute fix: set location to (offset) symbol value */
 224         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 225         add     r1, r10, r1             /* r1 <- address of symbol in table */
 226         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 227         add     r1, r1, r9              /* r1 <- relocated sym addr */
 228         b       fixnext
 229 fixrel:
 230         /* relative fix: increase location by offset */
 231         ldr     r1, [r0]
 232         add     r1, r1, r9
 233 fixnext:
 234         str     r1, [r0]
 235         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 236         cmp     r2, r3
 237         blo     fixloop
 238         b       clear_bss
 239 _rel_dyn_start_ofs:
 240         .word __rel_dyn_start - _start
 241 _rel_dyn_end_ofs:
 242         .word __rel_dyn_end - _start
 243 _dynsym_start_ofs:
 244         .word __dynsym_start - _start
 245
 246 #endif  /* #ifndef CONFIG_SPL_BUILD */
 247
 248 clear_bss:
 249 #ifdef CONFIG_SPL_BUILD
 250         /* No relocation for SPL */
 251         ldr     r0, =__bss_start
 252         ldr     r1, =__bss_end__
 253 #else
 254         ldr     r0, _bss_start_ofs
 255         ldr     r1, _bss_end_ofs
 256         mov     r4, r6                  /* reloc addr */
 257         add     r0, r0, r4
 258         add     r1, r1, r4
 259 #endif
 260         mov     r2, #0x00000000         /* clear                            */
 261
 262 clbss_l:str     r2, [r0]                /* clear loop...                    */
 263         add     r0, r0, #4
 264         cmp     r0, r1
 265         bne     clbss_l
 266
 267 /*
 268  * We are done. Do not return, instead branch to second part of board
 269  * initialization, now running from RAM.
 270  */
 271 jump_2_ram:
 272 /*
 273  * If I-cache is enabled invalidate it
 274  */
 275 #ifndef CONFIG_SYS_ICACHE_OFF
 276         mcr     p15, 0, r0, c7, c5, 0   @ invalidate icache
 277         mcr     p15, 0, r0, c7, c10, 4  @ DSB
 278         mcr     p15, 0, r0, c7, c5, 4   @ ISB
 279 #endif
 280         ldr     r0, _board_init_r_ofs
 281         adr     r1, _start
 282         add     lr, r0, r1
 283         add     lr, lr, r9
 284         /* setup parameters for board_init_r */
 285         mov     r0, r5          /* gd_t */
 286         mov     r1, r6          /* dest_addr */
 287         /* jump to it ... */
 288         mov     pc, lr
 289
 290 _board_init_r_ofs:
 291         .word board_init_r - _start
 292
 293 /*************************************************************************
 294  *
 295  * cpu_init_cp15
 296  *
 297  * Setup CP15 registers (cache, MMU, TLBs). The I-cache is turned on unless
 298  * CONFIG_SYS_ICACHE_OFF is defined.
 299  *
 300  *************************************************************************/
 301 .globl cpu_init_cp15
 302 cpu_init_cp15:
 303         /*
 304          * Invalidate L1 I/D
 305          */
 306         mov     r0, #0                  @ set up for MCR
 307         mcr     p15, 0, r0, c8, c7, 0   @ invalidate TLBs
 308         mcr     p15, 0, r0, c7, c5, 0   @ invalidate icache
 309         mcr     p15, 0, r0, c7, c5, 6   @ invalidate BP array
 310         mcr     p15, 0, r0, c7, c10, 4  @ DSB
 311         mcr     p15, 0, r0, c7, c5, 4   @ ISB
 312
 313         /*
 314          * disable MMU stuff and caches
 315          */
 316         mrc     p15, 0, r0, c1, c0, 0
 317         bic     r0, r0, #0x00002000     @ clear bits 13 (--V-)
 318         bic     r0, r0, #0x00000007     @ clear bits 2:0 (-CAM)
 319         orr     r0, r0, #0x00000002     @ set bit 1 (--A-) Align
 320         orr     r0, r0, #0x00000800     @ set bit 11 (Z---) BTB
 321 #ifdef CONFIG_SYS_ICACHE_OFF
 322         bic     r0, r0, #0x00001000     @ clear bit 12 (I) I-cache
 323 #else
 324         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-cache
 325 #endif
 326         mcr     p15, 0, r0, c1, c0, 0
 327         mov     pc, lr                  @ back to my caller
 328
 329
 330 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 331 /*************************************************************************
 332  *
 333  * CPU_init_critical registers
 334  *
 335  * setup important registers
 336  * setup memory timing
 337  *
 338  *************************************************************************/
 339 cpu_init_crit:
 340         /*
 341          * Jump to board specific initialization...
 342          * The Mask ROM will have already initialized
 343          * basic memory. Go here to bump up clock rate and handle
 344          * wake up conditions.
 345          */
 346         mov     ip, lr                  @ persevere link reg across call
 347         bl      lowlevel_init           @ go setup pll,mux,memory
 348         mov     lr, ip                  @ restore link
 349         mov     pc, lr                  @ back to my caller
 350 #endif
 351
 352 #ifndef CONFIG_SPL_BUILD
 353 /*
 354  *************************************************************************
 355  *
 356  * Interrupt handling
 357  *
 358  *************************************************************************
 359  */
 360 @
 361 @ IRQ stack frame.
 362 @
 363 #define S_FRAME_SIZE    72
 364
 365 #define S_OLD_R0        68
 366 #define S_PSR           64
 367 #define S_PC            60
 368 #define S_LR            56
 369 #define S_SP            52
 370
 371 #define S_IP            48
 372 #define S_FP            44
 373 #define S_R10           40
 374 #define S_R9            36
 375 #define S_R8            32
 376 #define S_R7            28
 377 #define S_R6            24
 378 #define S_R5            20
 379 #define S_R4            16
 380 #define S_R3            12
 381 #define S_R2            8
 382 #define S_R1            4
 383 #define S_R0            0
 384
 385 #define MODE_SVC 0x13
 386 #define I_BIT    0x80
 387
 388 /*
 389  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 390  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 391  */
 392
 393         .macro  bad_save_user_regs
 394         sub     sp, sp, #S_FRAME_SIZE           @ carve out a frame on current
 395                                                 @ user stack
 396         stmia   sp, {r0 - r12}                  @ Save user registers (now in
 397                                                 @ svc mode) r0-r12
 398         ldr     r2, IRQ_STACK_START_IN          @ set base 2 words into abort
 399                                                 @ stack
 400         ldmia   r2, {r2 - r3}                   @ get values for "aborted" pc
 401                                                 @ and cpsr (into parm regs)
 402         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 403
 404         add     r5, sp, #S_SP
 405         mov     r1, lr
 406         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 407         mov     r0, sp                          @ save current stack into r0
 408                                                 @ (param register)
 409         .endm
 410
 411         .macro  irq_save_user_regs
 412         sub     sp, sp, #S_FRAME_SIZE
 413         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 414         add     r8, sp, #S_PC                   @ !! R8 NEEDS to be saved !!
 415                                                 @ a reserved stack spot would
 416                                                 @ be good.
 417         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 418         str     lr, [r8, #0]                    @ Save calling PC
 419         mrs     r6, spsr
 420         str     r6, [r8, #4]                    @ Save CPSR
 421         str     r0, [r8, #8]                    @ Save OLD_R0
 422         mov     r0, sp
 423         .endm
 424
 425         .macro  irq_restore_user_regs
 426         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 427         mov     r0, r0
 428         ldr     lr, [sp, #S_PC]                 @ Get PC
 429         add     sp, sp, #S_FRAME_SIZE
 430         subs    pc, lr, #4                      @ return & move spsr_svc into
 431                                                 @ cpsr
 432         .endm
 433
 434         .macro get_bad_stack
 435         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack (enter
 436                                                 @ in banked mode)
 437
 438         str     lr, [r13]                       @ save caller lr in position 0
 439                                                 @ of saved stack
 440         mrs     lr, spsr                        @ get the spsr
 441         str     lr, [r13, #4]                   @ save spsr in position 1 of
 442                                                 @ saved stack
 443
 444         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 445         @ msr   spsr_c, r13
 446         msr     spsr, r13                       @ switch modes, make sure
 447                                                 @ moves will execute
 448         mov     lr, pc                          @ capture return pc
 449         movs    pc, lr                          @ jump to next instruction &
 450                                                 @ switch modes.
 451         .endm
 452
 453         .macro get_bad_stack_swi
 454         sub     r13, r13, #4                    @ space on current stack for
 455                                                 @ scratch reg.
 456         str     r0, [r13]                       @ save R0's value.
 457         ldr     r0, IRQ_STACK_START_IN          @ get data regions start
 458                                                 @ spots for abort stack
 459         str     lr, [r0]                        @ save caller lr in position 0
 460                                                 @ of saved stack
 461         mrs     r0, spsr                        @ get the spsr
 462         str     lr, [r0, #4]                    @ save spsr in position 1 of
 463                                                 @ saved stack
 464         ldr     r0, [r13]                       @ restore r0
 465         add     r13, r13, #4                    @ pop stack entry
 466         .endm
 467
 468         .macro get_irq_stack                    @ setup IRQ stack
 469         ldr     sp, IRQ_STACK_START
 470         .endm
 471
 472         .macro get_fiq_stack                    @ setup FIQ stack
 473         ldr     sp, FIQ_STACK_START
 474         .endm
 475
 476 /*
 477  * exception handlers
 478  */
 479         .align  5
 480 undefined_instruction:
 481         get_bad_stack
 482         bad_save_user_regs
 483         bl      do_undefined_instruction
 484
 485         .align  5
 486 software_interrupt:
 487         get_bad_stack_swi
 488         bad_save_user_regs
 489         bl      do_software_interrupt
 490
 491         .align  5
 492 prefetch_abort:
 493         get_bad_stack
 494         bad_save_user_regs
 495         bl      do_prefetch_abort
 496
 497         .align  5
 498 data_abort:
 499         get_bad_stack
 500         bad_save_user_regs
 501         bl      do_data_abort
 502
 503         .align  5
 504 not_used:
 505         get_bad_stack
 506         bad_save_user_regs
 507         bl      do_not_used
 508
 509 #ifdef CONFIG_USE_IRQ
 510
 511         .align  5
 512 irq:
 513         get_irq_stack
 514         irq_save_user_regs
 515         bl      do_irq
 516         irq_restore_user_regs
 517
 518         .align  5
 519 fiq:
 520         get_fiq_stack
 521         /* someone ought to write a more effective fiq_save_user_regs */
 522         irq_save_user_regs
 523         bl      do_fiq
 524         irq_restore_user_regs
 525
 526 #else
 527
 528         .align  5
 529 irq:
 530         get_bad_stack
 531         bad_save_user_regs
 532         bl      do_irq
 533
 534         .align  5
 535 fiq:
 536         get_bad_stack
 537         bad_save_user_regs
 538         bl      do_fiq
 539
 540 #endif /* CONFIG_USE_IRQ */
 541 #endif /* CONFIG_SPL_BUILD */