arch/blackfin/lib/memmove.S

   1 /*
   2  * File: memmove.S
   3  *
   4  * Copyright 2004-2007 Analog Devices Inc.
   5  * Enter bugs at http://blackfin.uclinux.org/
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License as published by
   9  * the Free Software Foundation; either version 2 of the License, or
  10  * (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, see the file COPYING, or write
  19  * to the Free Software Foundation, Inc.,
  20  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  21  */
  22
  23 .align 2
  24
  25 /*
  26  * C Library function MEMMOVE
  27  * R0 = To Address (leave unchanged to form result)
  28  * R1 = From Address
  29  * R2 = count
  30  * Data may overlap
  31  */
  32
  33 .globl _memmove;
  34 .type _memmove, STT_FUNC;
  35 _memmove:
  36         I1 = P3;
  37         P0 = R0;                  /* P0 = To address */
  38         P3 = R1;                  /* P3 = From Address */
  39         P2 = R2 ;                 /* P2 = count */
  40         CC = P2 == 0;             /* Check zero count*/
  41         IF CC JUMP .Lfinished;    /* very unlikely */
  42
  43         CC = R1 < R0 (IU);        /* From < To */
  44         IF !CC JUMP .Lno_overlap;
  45         R3 = R1 + R2;
  46         CC = R0 <= R3 (IU);       /* (From+len) >= To */
  47         IF CC JUMP .Loverlap;
  48 .Lno_overlap:
  49         R3 = 11;
  50         CC = R2 <= R3;
  51         IF CC JUMP  .Lbytes;
  52         R3 = R1 | R0;             /* OR addresses together */
  53         R3 <<= 30;                /* check bottom two bits */
  54         CC =  AZ;                 /* AZ set if zero.*/
  55         IF !CC JUMP  .Lbytes ;    /* Jump if addrs not aligned.*/
  56
  57         I0 = P3;
  58         P1 = P2 >> 2;             /* count = n/4 */
  59         P1 += -1;
  60         R3 =  3;
  61         R2 = R2 & R3;             /* remainder */
  62         P2 = R2;                  /* set remainder */
  63         R1 = [I0++];
  64
  65         LSETUP (.Lquad_loop , .Lquad_loop) LC0=P1;
  66 .Lquad_loop: MNOP || [P0++] = R1 || R1 = [I0++];
  67         [P0++] = R1;
  68
  69         CC = P2 == 0;             /* any remaining bytes? */
  70         P3 = I0;                  /* Ammend P3 to updated ptr. */
  71         IF !CC JUMP .Lbytes;
  72         P3 = I1;
  73         RTS;
  74
  75 .Lbytes:     LSETUP (.Lbyte2_s , .Lbyte2_e) LC0=P2;
  76 .Lbyte2_s:   R1 = B[P3++](Z);
  77 .Lbyte2_e:   B[P0++] = R1;
  78
  79 .Lfinished:  P3 = I1;
  80         RTS;
  81
  82 .Loverlap:
  83         P2 += -1;
  84         P0 = P0 + P2;
  85         P3 = P3 + P2;
  86         R1 = B[P3--] (Z);
  87         CC = P2 == 0;
  88         IF CC JUMP .Lno_loop;
  89         LSETUP (.Lol_s, .Lol_e) LC0 = P2;
  90 .Lol_s:    B[P0--] = R1;
  91 .Lol_e:    R1 = B[P3--] (Z);
  92 .Lno_loop: B[P0] = R1;
  93         P3 = I1;
  94         RTS;
  95
  96 .size _memmove, .-_memmove