arch/m68k/cpu/mcf532x/start.S

   1 /*
   2  * Copyright (C) 2003   Josef Baumgartner <josef.baumgartner@telex.de>
   3  * Based on code from Bernhard Kuhn <bkuhn@metrowerks.com>
   4  *
   5  * (C) Copyright 2004-2008 Freescale Semiconductor, Inc.
   6  * TsiChung Liew (Tsi-Chung.Liew@freescale.com)
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 #include <asm-offsets.h>
  28 #include <config.h>
  29 #include <timestamp.h>
  30 #include "version.h"
  31 #include <asm/cache.h>
  32
  33 #ifndef  CONFIG_IDENT_STRING
  34 #define  CONFIG_IDENT_STRING ""
  35 #endif
  36
  37 #define _START  _start
  38 #define _FAULT  _fault
  39
  40 #define SAVE_ALL                                                \
  41         move.w  #0x2700,%sr;            /* disable intrs */     \
  42         subl    #60,%sp;                /* space for 15 regs */ \
  43         moveml  %d0-%d7/%a0-%a6,%sp@;
  44
  45 #define RESTORE_ALL                                             \
  46         moveml  %sp@,%d0-%d7/%a0-%a6;                           \
  47         addl    #60,%sp;                /* space for 15 regs */ \
  48         rte;
  49
  50 #if !defined(CONFIG_MONITOR_IS_IN_RAM)
  51 .text
  52 /*
  53  *      Vector table. This is used for initial platform startup.
  54  *      These vectors are to catch any un-intended traps.
  55  */
  56 _vectors:
  57
  58 INITSP:         .long   0x00000000      /* Initial SP   */
  59 INITPC:         .long   _START  /* Initial PC           */
  60 vector02:       .long   _FAULT  /* Access Error         */
  61 vector03:       .long   _FAULT  /* Address Error        */
  62 vector04:       .long   _FAULT  /* Illegal Instruction  */
  63 vector05:       .long   _FAULT  /* Reserved             */
  64 vector06:       .long   _FAULT  /* Reserved             */
  65 vector07:       .long   _FAULT  /* Reserved             */
  66 vector08:       .long   _FAULT  /* Privilege Violation  */
  67 vector09:       .long   _FAULT  /* Trace                */
  68 vector0A:       .long   _FAULT  /* Unimplemented A-Line */
  69 vector0B:       .long   _FAULT  /* Unimplemented F-Line */
  70 vector0C:       .long   _FAULT  /* Debug Interrupt      */
  71 vector0D:       .long   _FAULT  /* Reserved             */
  72 vector0E:       .long   _FAULT  /* Format Error         */
  73 vector0F:       .long   _FAULT  /* Unitialized Int.     */
  74
  75 /* Reserved */
  76 vector10_17:
  77 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  78
  79 vector18:       .long   _FAULT  /* Spurious Interrupt   */
  80 vector19:       .long   _FAULT  /* Autovector Level 1   */
  81 vector1A:       .long   _FAULT  /* Autovector Level 2   */
  82 vector1B:       .long   _FAULT  /* Autovector Level 3   */
  83 vector1C:       .long   _FAULT  /* Autovector Level 4   */
  84 vector1D:       .long   _FAULT  /* Autovector Level 5   */
  85 vector1E:       .long   _FAULT  /* Autovector Level 6   */
  86 vector1F:       .long   _FAULT  /* Autovector Level 7   */
  87
  88 /* TRAP #0 - #15 */
  89 vector20_2F:
  90 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  91 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  92
  93 /* Reserved     */
  94 vector30_3F:
  95 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  96 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  97
  98 vector64_127:
  99 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 100 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 101 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 102 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 103 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 104 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 105 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 106 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 107
 108 vector128_191:
 109 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 110 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 111 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 112 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 113 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 114 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 115 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 116 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 117
 118 vector192_255:
 119 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 120 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 121 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 122 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 123 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 124 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 125 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 126 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 127 #endif /* !defined(CONFIG_MONITOR_IS_IN_RAM) */
 128
 129         .text
 130
 131         .globl  _start
 132 _start:
 133         nop
 134         nop
 135         move.w #0x2700,%sr      /* Mask off Interrupt */
 136
 137 #if !defined(CONFIG_MONITOR_IS_IN_RAM)
 138         /* Set vector base register at the beginning of the Flash */
 139         move.l  #CONFIG_SYS_FLASH_BASE, %d0
 140         movec   %d0, %VBR
 141 #endif
 142
 143         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_RAM_CTRL), %d0
 144         movec   %d0, %RAMBAR1
 145
 146         /* invalidate and disable cache */
 147         move.l  #CF_CACR_CINVA, %d0             /* Invalidate cache cmd */
 148         movec   %d0, %CACR                      /* Invalidate cache */
 149         move.l  #0, %d0
 150         movec   %d0, %ACR0
 151         movec   %d0, %ACR1
 152
 153 #ifdef CONFIG_MCF5301x
 154         move.l  #(0xFC0a0010), %a0
 155         move.w  (%a0), %d0
 156         and.l   %d0, 0xEFFF
 157
 158         move.w  %d0, (%a0)
 159 #endif
 160
 161         /* initialize general use internal ram */
 162         move.l #0, %d0
 163         move.l #(ICACHE_STATUS), %a1    /* icache */
 164         move.l #(DCACHE_STATUS), %a2    /* icache */
 165         move.l %d0, (%a1)
 166         move.l %d0, (%a2)
 167
 168         /* set stackpointer to end of internal ram to get some stackspace for the
 169            first c-code */
 170         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_SP_OFFSET), %sp
 171         clr.l %sp@-
 172
 173         move.l #__got_start, %a5        /* put relocation table address to a5 */
 174
 175         bsr cpu_init_f                  /* run low-level CPU init code (from flash) */
 176         bsr board_init_f                /* run low-level board init code (from flash) */
 177
 178         /* board_init_f() does not return */
 179
 180 /*------------------------------------------------------------------------------*/
 181
 182 /*
 183  * void relocate_code (addr_sp, gd, addr_moni)
 184  *
 185  * This "function" does not return, instead it continues in RAM
 186  * after relocating the monitor code.
 187  *
 188  * r3 = dest
 189  * r4 = src
 190  * r5 = length in bytes
 191  * r6 = cachelinesize
 192  */
 193         .globl  relocate_code
 194 relocate_code:
 195         link.w %a6,#0
 196         move.l 8(%a6), %sp              /* set new stack pointer */
 197
 198         move.l 12(%a6), %d0             /* Save copy of Global Data pointer */
 199         move.l 16(%a6), %a0             /* Save copy of Destination Address */
 200
 201         move.l #CONFIG_SYS_MONITOR_BASE, %a1
 202         move.l #__init_end, %a2
 203         move.l %a0, %a3
 204
 205         /* copy the code to RAM */
 206 1:
 207         move.l (%a1)+, (%a3)+
 208         cmp.l  %a1,%a2
 209         bgt.s    1b
 210
 211 /*
 212  * We are done. Do not return, instead branch to second part of board
 213  * initialization, now running from RAM.
 214  */
 215         move.l  %a0, %a1
 216         add.l   #(in_ram - CONFIG_SYS_MONITOR_BASE), %a1
 217         jmp     (%a1)
 218
 219 in_ram:
 220
 221 clear_bss:
 222         /*
 223          * Now clear BSS segment
 224          */
 225         move.l  %a0, %a1
 226         add.l   #(_sbss - CONFIG_SYS_MONITOR_BASE),%a1
 227         move.l  %a0, %d1
 228         add.l   #(_ebss - CONFIG_SYS_MONITOR_BASE),%d1
 229 6:
 230         clr.l   (%a1)+
 231         cmp.l   %a1,%d1
 232         bgt.s   6b
 233
 234         /*
 235          * fix got table in RAM
 236          */
 237         move.l  %a0, %a1
 238         add.l   #(__got_start - CONFIG_SYS_MONITOR_BASE),%a1
 239         move.l  %a1,%a5         /* * fix got pointer register a5 */
 240
 241         move.l  %a0, %a2
 242         add.l   #(__got_end - CONFIG_SYS_MONITOR_BASE),%a2
 243
 244 7:
 245         move.l  (%a1),%d1
 246         sub.l   #_start,%d1
 247         add.l   %a0,%d1
 248         move.l  %d1,(%a1)+
 249         cmp.l   %a2, %a1
 250         bne     7b
 251
 252         /* calculate relative jump to board_init_r in ram */
 253         move.l %a0, %a1
 254         add.l #(board_init_r - CONFIG_SYS_MONITOR_BASE), %a1
 255
 256         /* set parameters for board_init_r */
 257         move.l %a0,-(%sp)               /* dest_addr */
 258         move.l %d0,-(%sp)               /* gd */
 259         jsr     (%a1)
 260
 261 /*------------------------------------------------------------------------------*/
 262 /* exception code */
 263         .globl _fault
 264 _fault:
 265         jmp _fault
 266         .globl  _exc_handler
 267
 268 _exc_handler:
 269         SAVE_ALL
 270         movel   %sp,%sp@-
 271         bsr exc_handler
 272         addql   #4,%sp
 273         RESTORE_ALL
 274
 275         .globl  _int_handler
 276 _int_handler:
 277         SAVE_ALL
 278         movel   %sp,%sp@-
 279         bsr int_handler
 280         addql   #4,%sp
 281         RESTORE_ALL
 282
 283 /*------------------------------------------------------------------------------*/
 284         .globl  version_string
 285 version_string:
 286         .ascii U_BOOT_VERSION
 287         .ascii " (", U_BOOT_DATE, " - ", U_BOOT_TIME, ")"
 288         .ascii CONFIG_IDENT_STRING, "\0"
 289         .align 4