arch/x86/cpu/start.S

   1 /*
   2  *  U-boot - x86 Startup Code
   3  *
   4  * (C) Copyright 2008-2011
   5  * Graeme Russ, <graeme.russ@gmail.com>
   6  *
   7  * (C) Copyright 2002
   8  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
   9  *
  10  * See file CREDITS for list of people who contributed to this
  11  * project.
  12  *
  13  * This program is free software; you can redistribute it and/or
  14  * modify it under the terms of the GNU General Public License as
  15  * published by the Free Software Foundation; either version 2 of
  16  * the License, or (at your option) any later version.
  17  *
  18  * This program is distributed in the hope that it will be useful,
  19  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  20  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21  * GNU General Public License for more details.
  22  *
  23  * You should have received a copy of the GNU General Public License
  24  * along with this program; if not, write to the Free Software
  25  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  26  * MA 02111-1307 USA
  27  */
  28
  29 #include <config.h>
  30 #include <version.h>
  31 #include <asm/global_data.h>
  32 #include <asm/processor-flags.h>
  33
  34 .section .text
  35 .code32
  36 .globl _start
  37 .type _start, @function
  38 .globl _x86boot_start
  39 _x86boot_start:
  40         /*
  41          * This is the fail safe 32-bit bootstrap entry point. The
  42          * following code is not executed from a cold-reset (actually, a
  43          * lot of it is, but from real-mode after cold reset. It is
  44          * repeated here to put the board into a state as close to cold
  45          * reset as necessary)
  46          */
  47         cli
  48         cld
  49
  50         /* Turn of cache (this might require a 486-class CPU) */
  51         movl    %cr0, %eax
  52         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  53         movl    %eax, %cr0
  54         wbinvd
  55
  56         /* Tell 32-bit code it is being entered from an in-RAM copy */
  57         movw    $GD_FLG_WARM_BOOT, %bx
  58 _start:
  59         /* This is the 32-bit cold-reset entry point */
  60
  61         /* Load the segement registes to match the gdt loaded in start16.S */
  62         movl    $0x18, %eax
  63         movw    %ax, %fs
  64         movw    %ax, %ds
  65         movw    %ax, %gs
  66         movw    %ax, %es
  67         movw    %ax, %ss
  68
  69         /* Clear the interupt vectors */
  70         lidt    blank_idt_ptr
  71
  72         /* Early platform init (setup gpio, etc ) */
  73         jmp     early_board_init
  74 .globl early_board_init_ret
  75 early_board_init_ret:
  76
  77         /* Initialise Cache-As-RAM */
  78         jmp     car_init
  79 .globl car_init_ret
  80 car_init_ret:
  81         /*
  82          * We now have CONFIG_SYS_CAR_SIZE bytes of Cache-As-RAM (or SRAM,
  83          * or fully initialised SDRAM - we really don't care which)
  84          * starting at CONFIG_SYS_CAR_ADDR to be used as a temporary stack
  85          */
  86         movl    $CONFIG_SYS_INIT_SP_ADDR, %esp
  87
  88         /* Set parameter to board_init_f() to boot flags */
  89         xorl    %eax, %eax
  90         movw    %bx, %ax
  91
  92         /* Enter, U-boot! */
  93         call    board_init_f
  94
  95         /* indicate (lack of) progress */
  96         movw    $0x85, %ax
  97         jmp     die
  98
  99 .globl relocate_code
 100 .type relocate_code, @function
 101 relocate_code:
 102         /*
 103          * SDRAM has been initialised, U-Boot code has been copied into
 104          * RAM, BSS has been cleared and relocation adjustments have been
 105          * made. It is now time to jump into the in-RAM copy of U-Boot
 106          *
 107          * %eax = Address of top of stack
 108          * %edx = Address of Global Data
 109          * %ecx = Base address of in-RAM copy of U-Boot
 110          */
 111
 112         /* Setup stack in RAM */
 113         movl    %eax, %esp
 114
 115         /* Setup call address of in-RAM copy of board_init_r() */
 116         movl    $board_init_r, %ebp
 117         addl    (GD_RELOC_OFF * 4)(%edx), %ebp
 118
 119         /* Setup parameters to board_init_r() */
 120         movl    %edx, %eax
 121         movl    %ecx, %edx
 122
 123         /* Jump to in-RAM copy of board_init_r() */
 124         call    *%ebp
 125
 126 die:    hlt
 127         jmp     die
 128         hlt
 129
 130 blank_idt_ptr:
 131         .word   0               /* limit */
 132         .long   0               /* base */