arch/x86/cpu/start.S

   1 /*
   2  *  U-Boot - x86 Startup Code
   3  *
   4  * (C) Copyright 2008-2011
   5  * Graeme Russ, <graeme.russ@gmail.com>
   6  *
   7  * (C) Copyright 2002
   8  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
   9  *
  10  * SPDX-License-Identifier:     GPL-2.0+
  11  */
  12
  13 #include <config.h>
  14 #include <asm/global_data.h>
  15 #include <asm/post.h>
  16 #include <asm/processor.h>
  17 #include <asm/processor-flags.h>
  18 #include <generated/generic-asm-offsets.h>
  19 #include <generated/asm-offsets.h>
  20
  21 .section .text
  22 .code32
  23 .globl _start
  24 .type _start, @function
  25 .globl _x86boot_start
  26 _x86boot_start:
  27         /*
  28          * This is the fail-safe 32-bit bootstrap entry point.
  29          *
  30          * This code is used when booting from another boot loader like
  31          * coreboot or EFI. So we repeat some of the same init found in
  32          * start16.
  33          */
  34         cli
  35         cld
  36
  37         /* Turn off cache (this might require a 486-class CPU) */
  38         movl    %cr0, %eax
  39         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  40         movl    %eax, %cr0
  41         wbinvd
  42
  43         /* Tell 32-bit code it is being entered from an in-RAM copy */
  44         movl    $GD_FLG_WARM_BOOT, %ebx
  45
  46         /*
  47          * Zero the BIST (Built-In Self Test) value since we don't have it.
  48          * It must be 0 or the previous loader would have reported an error.
  49          */
  50         movl    $0, %ebp
  51
  52         jmp     1f
  53
  54         /* Add a way for tools to discover the _start entry point */
  55         .align  4
  56         .long   0x12345678
  57 _start:
  58         /*
  59          * This is the 32-bit cold-reset entry point, coming from start16.
  60          * Set %ebx to GD_FLG_COLD_BOOT to indicate this.
  61          */
  62         movl    $GD_FLG_COLD_BOOT, %ebx
  63
  64         /* Save BIST */
  65         movl    %eax, %ebp
  66 1:
  67
  68         /* Save table pointer */
  69         movl    %ecx, %esi
  70
  71         /* Load the segement registers to match the GDT loaded in start16.S */
  72         movl    $(X86_GDT_ENTRY_32BIT_DS * X86_GDT_ENTRY_SIZE), %eax
  73         movw    %ax, %fs
  74         movw    %ax, %ds
  75         movw    %ax, %gs
  76         movw    %ax, %es
  77         movw    %ax, %ss
  78
  79         /* Clear the interrupt vectors */
  80         lidt    blank_idt_ptr
  81
  82         /*
  83          * Critical early platform init - generally not used, we prefer init
  84          * to happen later when we have a console, in case something goes
  85          * wrong.
  86          */
  87         jmp     early_board_init
  88 .globl early_board_init_ret
  89 early_board_init_ret:
  90         post_code(POST_START)
  91
  92         /* Initialise Cache-As-RAM */
  93         jmp     car_init
  94 .globl car_init_ret
  95 car_init_ret:
  96 #ifndef CONFIG_HAVE_FSP
  97         /*
  98          * We now have CONFIG_SYS_CAR_SIZE bytes of Cache-As-RAM (or SRAM,
  99          * or fully initialised SDRAM - we really don't care which)
 100          * starting at CONFIG_SYS_CAR_ADDR to be used as a temporary stack
 101          * and early malloc() area. The MRC requires some space at the top.
 102          *
 103          * Stack grows down from top of CAR. We have:
 104          *
 105          * top-> CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE
 106          *      MRC area
 107          *      global_data
 108          *      x86 global descriptor table
 109          *      early malloc area
 110          *      stack
 111          * bottom-> CONFIG_SYS_CAR_ADDR
 112          */
 113         movl    $(CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE - 4), %esp
 114 #ifdef CONFIG_DCACHE_RAM_MRC_VAR_SIZE
 115         subl    $CONFIG_DCACHE_RAM_MRC_VAR_SIZE, %esp
 116 #endif
 117 #else
 118         /*
 119          * When we get here after car_init(), esp points to a temporary stack
 120          * and esi holds the HOB list address returned by the FSP.
 121          */
 122 #endif
 123
 124         /* Reserve space on stack for global data */
 125         subl    $GENERATED_GBL_DATA_SIZE, %esp
 126
 127         /* Align global data to 16-byte boundary */
 128         andl    $0xfffffff0, %esp
 129         post_code(POST_START_STACK)
 130
 131         /* Zero the global data since it won't happen later */
 132         xorl    %eax, %eax
 133         movl    $GENERATED_GBL_DATA_SIZE, %ecx
 134         movl    %esp, %edi
 135         rep     stosb
 136
 137 #ifdef CONFIG_HAVE_FSP
 138         test    %esi, %esi
 139         jz      skip_hob
 140
 141         /* Store HOB list */
 142         movl    %esp, %edx
 143         addl    $GD_HOB_LIST, %edx
 144         movl    %esi, (%edx)
 145
 146 skip_hob:
 147 #else
 148         /* Store table pointer */
 149         movl    %esp, %edx
 150         addl    $GD_TABLE, %edx
 151         movl    %esi, (%edx)
 152 #endif
 153
 154         /* Setup first parameter to setup_gdt, pointer to global_data */
 155         movl    %esp, %eax
 156
 157         /* Reserve space for global descriptor table */
 158         subl    $X86_GDT_SIZE, %esp
 159
 160         /* Align temporary global descriptor table to 16-byte boundary */
 161         andl    $0xfffffff0, %esp
 162         movl    %esp, %ecx
 163
 164 #if defined(CONFIG_SYS_MALLOC_F_LEN)
 165         /* Set up the pre-relocation malloc pool */
 166         subl    $CONFIG_SYS_MALLOC_F_LEN, %esp
 167         movl    %eax, %edx
 168         addl    $GD_MALLOC_BASE, %edx
 169         movl    %esp, (%edx)
 170 #endif
 171         /* Store BIST into global_data */
 172         movl    %eax, %edx
 173         addl    $GD_BIST, %edx
 174         movl    %ebp, (%edx)
 175
 176         /* Set second parameter to setup_gdt() */
 177         movl    %ecx, %edx
 178
 179         /* Setup global descriptor table so gd->xyz works */
 180         call    setup_gdt
 181
 182         /* Set parameter to board_init_f() to boot flags */
 183         post_code(POST_START_DONE)
 184         xorl    %eax, %eax
 185
 186         /* Enter, U-Boot! */
 187         call    board_init_f
 188
 189         /* indicate (lack of) progress */
 190         movw    $0x85, %ax
 191         jmp     die
 192
 193 .globl board_init_f_r_trampoline
 194 .type board_init_f_r_trampoline, @function
 195 board_init_f_r_trampoline:
 196         /*
 197          * SDRAM has been initialised, U-Boot code has been copied into
 198          * RAM, BSS has been cleared and relocation adjustments have been
 199          * made. It is now time to jump into the in-RAM copy of U-Boot
 200          *
 201          * %eax = Address of top of new stack
 202          */
 203
 204         /* Stack grows down from top of SDRAM */
 205         movl    %eax, %esp
 206
 207         /* Reserve space on stack for global data */
 208         subl    $GENERATED_GBL_DATA_SIZE, %esp
 209
 210         /* Align global data to 16-byte boundary */
 211         andl    $0xfffffff0, %esp
 212
 213         /* Setup first parameter to memcpy() and setup_gdt() */
 214         movl    %esp, %eax
 215
 216         /* Setup second parameter to memcpy() */
 217         fs movl 0, %edx
 218
 219         /* Set third parameter to memcpy() */
 220         movl    $GENERATED_GBL_DATA_SIZE, %ecx
 221
 222         /* Copy global data from CAR to SDRAM stack */
 223         call    memcpy
 224
 225         /* Reserve space for global descriptor table */
 226         subl    $X86_GDT_SIZE, %esp
 227
 228         /* Align global descriptor table to 16-byte boundary */
 229         andl    $0xfffffff0, %esp
 230
 231         /* Set second parameter to setup_gdt() */
 232         movl    %esp, %edx
 233
 234         /* Setup global descriptor table so gd->xyz works */
 235         call    setup_gdt
 236
 237         /* Set if we need to disable CAR */
 238 .weak   car_uninit
 239         movl    $car_uninit, %eax
 240         cmpl    $0, %eax
 241         jz      1f
 242
 243         call    car_uninit
 244 1:
 245         /* Re-enter U-Boot by calling board_init_f_r() */
 246         call    board_init_f_r
 247
 248 die:
 249         hlt
 250         jmp     die
 251         hlt
 252
 253 blank_idt_ptr:
 254         .word   0               /* limit */
 255         .long   0               /* base */
 256
 257         .p2align        2       /* force 4-byte alignment */
 258
 259         /* Add a multiboot header so U-Boot can be loaded by GRUB2 */
 260 multiboot_header:
 261         /* magic */
 262         .long   0x1badb002
 263         /* flags */
 264         .long   (1 << 16)
 265         /* checksum */
 266         .long   -0x1BADB002 - (1 << 16)
 267         /* header addr */
 268         .long   multiboot_header - _x86boot_start + CONFIG_SYS_TEXT_BASE
 269         /* load addr */
 270         .long   CONFIG_SYS_TEXT_BASE
 271         /* load end addr */
 272         .long   0
 273         /* bss end addr */
 274         .long   0
 275         /* entry addr */
 276         .long   CONFIG_SYS_TEXT_BASE