arch/x86/cpu/u-boot.lds

   1 /*
   2  * (C) Copyright 2002
   3  * Daniel Engström, Omicron Ceti AB, daniel@omicron.se.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 #include <config.h>
  25 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  26 OUTPUT_ARCH(i386)
  27 ENTRY(_start)
  28
  29 SECTIONS
  30 {
  31         . = CONFIG_SYS_TEXT_BASE;       /* Location of bootcode in flash */
  32         __text_start = .;
  33         .text  : { *(.text*); }
  34
  35         . = ALIGN(4);
  36         __u_boot_cmd_start = .;
  37         .u_boot_cmd : { *(.u_boot_cmd) }
  38         . = ALIGN(4);
  39         __u_boot_cmd_end = .;
  40
  41         . = ALIGN(4);
  42         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  43
  44         . = ALIGN(4);
  45         .data : { *(.data*) }
  46
  47         . = ALIGN(4);
  48         .dynsym : { *(.dynsym*) }
  49
  50         . = ALIGN(4);
  51         .hash : { *(.hash*) }
  52
  53         . = ALIGN(4);
  54         .got : { *(.got*) }
  55
  56         . = ALIGN(4);
  57         __data_end = .;
  58
  59         . = ALIGN(4);
  60         __bss_start = ABSOLUTE(.);
  61         .bss (NOLOAD) : { *(.bss) }
  62         . = ALIGN(4);
  63         __bss_end = ABSOLUTE(.);
  64
  65         . = ALIGN(4);
  66         __rel_dyn_start = .;
  67         .rel.dyn : { *(.rel.dyn) }
  68         __rel_dyn_end = .;
  69
  70         /DISCARD/ : { *(.dynstr*) }
  71         /DISCARD/ : { *(.dynamic*) }
  72         /DISCARD/ : { *(.plt*) }
  73         /DISCARD/ : { *(.interp*) }
  74         /DISCARD/ : { *(.gnu*) }
  75
  76         /* 16bit realmode trampoline code */
  77         .realmode REALMODE_BASE : AT ( LOADADDR(.rel.dyn) + SIZEOF(.rel.dyn) ) { KEEP(*(.realmode)) }
  78
  79         __realmode_start = LOADADDR(.realmode);
  80         __realmode_size = SIZEOF(.realmode);
  81
  82         /* 16bit BIOS emulation code (just enough to boot Linux) */
  83         .bios 0 : AT ( LOADADDR(.realmode) + SIZEOF(.realmode) ) { KEEP(*(.bios)) }
  84
  85         __bios_start = LOADADDR(.bios);
  86         __bios_size = SIZEOF(.bios);
  87
  88         /*
  89          * The following expressions place the 16-bit Real-Mode code and
  90          * Reset Vector at the end of the Flash ROM
  91          */
  92         . = START_16;
  93         .start16 : AT (CONFIG_SYS_TEXT_BASE + (CONFIG_SYS_MONITOR_LEN - RESET_SEG_SIZE + START_16)) { KEEP(*(.start16)); }
  94
  95         . = RESET_VEC_LOC;
  96         .resetvec : AT (CONFIG_SYS_TEXT_BASE + (CONFIG_SYS_MONITOR_LEN - RESET_SEG_SIZE + RESET_VEC_LOC)) { KEEP(*(.resetvec)); }
  97 }