arch/x86/cpu/u-boot.lds

   1 /*
   2  * (C) Copyright 2002
   3  * Daniel Engström, Omicron Ceti AB, daniel@omicron.se.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 #include <config.h>
  25 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  26 OUTPUT_ARCH(i386)
  27 ENTRY(_start)
  28
  29 SECTIONS
  30 {
  31         . = CONFIG_SYS_TEXT_BASE;       /* Location of bootcode in flash */
  32         __text_start = .;
  33         .text  : { *(.text*); }
  34
  35         . = ALIGN(4);
  36         __u_boot_cmd_start = .;
  37         .u_boot_cmd : { *(.u_boot_cmd) }
  38         . = ALIGN(4);
  39         __u_boot_cmd_end = .;
  40
  41         . = ALIGN(4);
  42         .u_boot_list : {
  43         #include <u-boot.lst>
  44         }
  45
  46         . = ALIGN(4);
  47         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  48
  49         . = ALIGN(4);
  50         .data : { *(.data*) }
  51
  52         . = ALIGN(4);
  53         .dynsym : { *(.dynsym*) }
  54
  55         . = ALIGN(4);
  56         .hash : { *(.hash*) }
  57
  58         . = ALIGN(4);
  59         .got : { *(.got*) }
  60
  61         . = ALIGN(4);
  62         __data_end = .;
  63
  64         . = ALIGN(4);
  65         __bss_start = ABSOLUTE(.);
  66         .bss (NOLOAD) : { *(.bss) }
  67         . = ALIGN(4);
  68         __bss_end = ABSOLUTE(.);
  69
  70         . = ALIGN(4);
  71         __rel_dyn_start = .;
  72         .rel.dyn : { *(.rel.dyn) }
  73         __rel_dyn_end = .;
  74
  75         /DISCARD/ : { *(.dynstr*) }
  76         /DISCARD/ : { *(.dynamic*) }
  77         /DISCARD/ : { *(.plt*) }
  78         /DISCARD/ : { *(.interp*) }
  79         /DISCARD/ : { *(.gnu*) }
  80
  81         /* 16bit realmode trampoline code */
  82         .realmode REALMODE_BASE : AT ( LOADADDR(.rel.dyn) + SIZEOF(.rel.dyn) ) { KEEP(*(.realmode)) }
  83
  84         __realmode_start = LOADADDR(.realmode);
  85         __realmode_size = SIZEOF(.realmode);
  86
  87         /* 16bit BIOS emulation code (just enough to boot Linux) */
  88         .bios 0 : AT ( LOADADDR(.realmode) + SIZEOF(.realmode) ) { KEEP(*(.bios)) }
  89
  90         __bios_start = LOADADDR(.bios);
  91         __bios_size = SIZEOF(.bios);
  92
  93         /*
  94          * The following expressions place the 16-bit Real-Mode code and
  95          * Reset Vector at the end of the Flash ROM
  96          */
  97         . = START_16;
  98         .start16 : AT (CONFIG_SYS_TEXT_BASE + (CONFIG_SYS_MONITOR_LEN - RESET_SEG_SIZE + START_16)) { KEEP(*(.start16)); }
  99
 100         . = RESET_VEC_LOC;
 101         .resetvec : AT (CONFIG_SYS_TEXT_BASE + (CONFIG_SYS_MONITOR_LEN - RESET_SEG_SIZE + RESET_VEC_LOC)) { KEEP(*(.resetvec)); }
 102 }