board/cogent/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 #include <config.h>
   9 OUTPUT_ARCH(powerpc)
  10
  11 SECTIONS
  12 {
  13   /* Read-only sections, merged into text segment: */
  14   . = + SIZEOF_HEADERS;
  15   .text      :
  16   {
  17 #ifdef CONFIG_MPC8260
  18     arch/powerpc/cpu/mpc8260/start.o    (.text*)
  19 #else
  20     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  21     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  22 #endif
  23     *(.text*)
  24   }
  25   _etext = .;
  26   PROVIDE (etext = .);
  27   .rodata    :
  28   {
  29     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  30   }
  31
  32   /* Read-write section, merged into data segment: */
  33   . = (. + 0x0FFF) & 0xFFFFF000;
  34   _erotext = .;
  35   PROVIDE (erotext = .);
  36   .reloc   :
  37   {
  38     _GOT2_TABLE_ = .;
  39     KEEP(*(.got2))
  40     KEEP(*(.got))
  41     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  42     _FIXUP_TABLE_ = .;
  43     KEEP(*(.fixup))
  44   }
  45   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  46   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  47
  48   .data    :
  49   {
  50     *(.data*)
  51     *(.sdata*)
  52   }
  53   _edata  =  .;
  54   PROVIDE (edata = .);
  55
  56   . = .;
  57
  58   . = ALIGN(4);
  59   .u_boot_list : {
  60         KEEP(*(SORT(.u_boot_list*)));
  61   }
  62
  63
  64   . = .;
  65   __start___ex_table = .;
  66   __ex_table : { *(__ex_table) }
  67   __stop___ex_table = .;
  68
  69   . = ALIGN(4096);
  70   __init_begin = .;
  71   .text.init : { *(.text.init) }
  72   .data.init : { *(.data.init) }
  73   . = ALIGN(4096);
  74   __init_end = .;
  75
  76   __bss_start = .;
  77   .bss (NOLOAD)       :
  78   {
  79    *(.bss*)
  80    *(.sbss*)
  81    *(COMMON)
  82    . = ALIGN(4);
  83   }
  84   __bss_end = . ;
  85   PROVIDE (end = .);
  86 }