board/eNET/u-boot.lds

   1 /*
   2  * (C) Copyright 2002
   3  * Daniel Engström, Omicron Ceti AB, daniel@omicron.se.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  25 OUTPUT_ARCH(i386)
  26 ENTRY(_start)
  27
  28 SECTIONS
  29 {
  30         . = 0x38040000;         /* Location of bootcode in flash */
  31         .text  : { *(.text); }
  32
  33         . = ALIGN(4);
  34         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  35
  36         _i386boot_text_size = SIZEOF(.text) + SIZEOF(.rodata);
  37
  38         . = 0x03FF0000;         /* Ram data segment to use */
  39         _i386boot_romdata_dest = ABSOLUTE(.);
  40         .data : AT ( LOADADDR(.rodata) + SIZEOF(.rodata) ) { *(.data) }
  41         _i386boot_romdata_start = LOADADDR(.data);
  42
  43         . = ALIGN(4);
  44         .got : AT ( LOADADDR(.data) + SIZEOF(.data) ) { *(.got) }
  45
  46         . = ALIGN(4);
  47         __u_boot_cmd_start = .;
  48         .u_boot_cmd : { *(.u_boot_cmd) }
  49         __u_boot_cmd_end = .;
  50         _i386boot_cmd_start = LOADADDR(.u_boot_cmd);
  51
  52         _i386boot_romdata_size = SIZEOF(.data) + SIZEOF(.got) + SIZEOF(.u_boot_cmd);
  53
  54         . = ALIGN(4);
  55         _i386boot_bss_start = ABSOLUTE(.);
  56         .bss (NOLOAD) : { *(.bss) }
  57         _i386boot_bss_size = SIZEOF(.bss);
  58
  59         /* 16bit realmode trampoline code */
  60         .realmode 0x7c0 : AT ( LOADADDR(.got) + SIZEOF(.got) + SIZEOF(.u_boot_cmd)) { *(.realmode) }
  61
  62         _i386boot_realmode = LOADADDR(.realmode);
  63         _i386boot_realmode_size = SIZEOF(.realmode);
  64
  65         /* 16bit BIOS emulation code (just enough to boot Linux) */
  66         .bios 0 : AT ( LOADADDR(.realmode) + SIZEOF(.realmode) ) { *(.bios) }
  67
  68         _i386boot_bios = LOADADDR(.bios);
  69         _i386boot_bios_size = SIZEOF(.bios);
  70
  71         /* The load addresses below assumes that the flash
  72          * will be mapped so that 0x387f0000 == 0xffff0000
  73          * at reset time
  74          *
  75          * The fe00 and ff00 offsets of the start32 and start16
  76          * segments are arbitrary, the just have to be mapped
  77          * at reset and the code have to fit.
  78          * The fff0 offset of resetvec is important, however.
  79          */
  80
  81         . = 0xfffffe00;
  82         .start32 : AT (0x3807fe00) { *(.start32); }
  83
  84         . = 0xf800;
  85         .start16 : AT (0x3807f800) { *(.start16); }
  86
  87         . = 0xfff0;
  88         .resetvec : AT (0x3807fff0) { *(.resetvec); }
  89         _i386boot_end = (LOADADDR(.resetvec) + SIZEOF(.resetvec) );
  90 }