board/ezkit533/u-boot.lds

   1 /*
   2  * U-boot - u-boot.lds
   3  *
   4  * Copyright (c) 2005 blackfin.uclinux.org
   5  *
   6  * (C) Copyright 2000-2004
   7  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   8  *
   9  * See file CREDITS for list of people who contributed to this
  10  * project.
  11  *
  12  * This program is free software; you can redistribute it and/or
  13  * modify it under the terms of the GNU General Public License as
  14  * published by the Free Software Foundation; either version 2 of
  15  * the License, or (at your option) any later version.
  16  *
  17  * This program is distributed in the hope that it will be useful,
  18  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  19  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20  * GNU General Public License for more details.
  21  *
  22  * You should have received a copy of the GNU General Public License
  23  * along with this program; if not, write to the Free Software
  24  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  25  * MA 02111-1307 USA
  26  */
  27
  28 OUTPUT_ARCH(bfin)
  29 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib);
  30 /* Do we need any of these for elf?
  31    __DYNAMIC = 0;    */
  32 SECTIONS
  33 {
  34   /* Read-only sections, merged into text segment: */
  35   . = + SIZEOF_HEADERS;
  36   .interp : { *(.interp) }
  37   .hash          : { *(.hash)           }
  38   .dynsym        : { *(.dynsym)         }
  39   .dynstr        : { *(.dynstr)         }
  40   .rel.text      : { *(.rel.text)       }
  41   .rela.text     : { *(.rela.text)      }
  42   .rel.data      : { *(.rel.data)       }
  43   .rela.data     : { *(.rela.data)      }
  44   .rel.rodata    : { *(.rel.rodata)     }
  45   .rela.rodata   : { *(.rela.rodata)    }
  46   .rel.got       : { *(.rel.got)        }
  47   .rela.got      : { *(.rela.got)       }
  48   .rel.ctors     : { *(.rel.ctors)      }
  49   .rela.ctors    : { *(.rela.ctors)     }
  50   .rel.dtors     : { *(.rel.dtors)      }
  51   .rela.dtors    : { *(.rela.dtors)     }
  52   .rel.bss       : { *(.rel.bss)        }
  53   .rela.bss      : { *(.rela.bss)       }
  54   .rel.plt       : { *(.rel.plt)        }
  55   .rela.plt      : { *(.rela.plt)       }
  56   .init          : { *(.init)           }
  57   .plt : { *(.plt) }
  58   .text      :
  59   {
  60     /* WARNING - the following is hand-optimized to fit within  */
  61     /* the sector before the environment sector. If it throws   */
  62     /* an error during compilation remove an object here to get */
  63     /* it linked after the configuration sector.                */
  64
  65     cpu/bf533/start.o           (.text)
  66     cpu/bf533/start1.o          (.text)
  67     cpu/bf533/traps.o           (.text)
  68     cpu/bf533/interrupt.o       (.text)
  69     cpu/bf533/serial.o          (.text)
  70     common/dlmalloc.o           (.text)
  71     lib_generic/vsprintf.o      (.text)
  72     lib_generic/crc32.o         (.text)
  73     lib_generic/zlib.o          (.text)
  74     board/ezkit533/ezkit533.o           (.text)
  75
  76     . = DEFINED(env_offset) ? env_offset : .;
  77     common/environment.o        (.text)
  78
  79     *(.text)
  80     *(.fixup)
  81     *(.got1)
  82   }
  83   _etext = .;
  84   PROVIDE (etext = .);
  85   .rodata    :
  86   {
  87     *(.rodata)
  88     *(.rodata1)
  89     *(.rodata.str1.4)
  90   }
  91   .fini      : { *(.fini)    } =0
  92   .ctors     : { *(.ctors)   }
  93   .dtors     : { *(.dtors)   }
  94
  95   /* Read-write section, merged into data segment: */
  96   . = (. + 0x00FF) & 0xFFFFFF00;
  97   _erotext = .;
  98   PROVIDE (erotext = .);
  99   .reloc   :
 100   {
 101     *(.got)
 102     _GOT2_TABLE_ = .;
 103     *(.got2)
 104     _FIXUP_TABLE_ = .;
 105     *(.fixup)
 106   }
 107   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 108   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 109
 110   .data    :
 111   {
 112     *(.data)
 113     *(.data1)
 114     *(.sdata)
 115     *(.sdata2)
 116     *(.dynamic)
 117     CONSTRUCTORS
 118   }
 119   _edata  =  .;
 120   PROVIDE (edata = .);
 121
 122   __u_boot_cmd_start = .;
 123   .u_boot_cmd : { *(.u_boot_cmd) }
 124   __u_boot_cmd_end = .;
 125
 126
 127   __start___ex_table = .;
 128   __ex_table : { *(__ex_table) }
 129   __stop___ex_table = .;
 130
 131   . = ALIGN(256);
 132   __init_begin = .;
 133   .text.init : { *(.text.init) }
 134   .data.init : { *(.data.init) }
 135   . = ALIGN(256);
 136   __init_end = .;
 137
 138   __bss_start = .;
 139   .bss       :
 140   {
 141    *(.sbss) *(.scommon)
 142    *(.dynbss)
 143    *(.bss)
 144    *(COMMON)
 145   }
 146   _end = . ;
 147   PROVIDE (end = .);
 148 }
 149