board/freescale/mpc8560ads/u-boot.lds

   1 /*
   2  * (C) Copyright 2002,2003, Motorola,Inc.
   3  * Xianghua Xiao, X.Xiao@motorola.com.
   4  *
   5  * Copyright 2008 Freescale Semiconductor, Inc.
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_ARCH(powerpc)
  27 /* Do we need any of these for elf?
  28    __DYNAMIC = 0;    */
  29 SECTIONS
  30 {
  31   /* Read-only sections, merged into text segment: */
  32   . = + SIZEOF_HEADERS;
  33   .interp : { *(.interp) }
  34   .hash          : { *(.hash)           }
  35   .dynsym        : { *(.dynsym)         }
  36   .dynstr        : { *(.dynstr)         }
  37   .rel.text      : { *(.rel.text)               }
  38   .rela.text     : { *(.rela.text)      }
  39   .rel.data      : { *(.rel.data)               }
  40   .rela.data     : { *(.rela.data)      }
  41   .rel.rodata    : { *(.rel.rodata)     }
  42   .rela.rodata   : { *(.rela.rodata)    }
  43   .rel.got       : { *(.rel.got)                }
  44   .rela.got      : { *(.rela.got)               }
  45   .rel.ctors     : { *(.rel.ctors)      }
  46   .rela.ctors    : { *(.rela.ctors)     }
  47   .rel.dtors     : { *(.rel.dtors)      }
  48   .rela.dtors    : { *(.rela.dtors)     }
  49   .rel.bss       : { *(.rel.bss)                }
  50   .rela.bss      : { *(.rela.bss)               }
  51   .rel.plt       : { *(.rel.plt)                }
  52   .rela.plt      : { *(.rela.plt)               }
  53   .init          : { *(.init)   }
  54   .plt : { *(.plt) }
  55   .text      :
  56   {
  57     *(.text)
  58     *(.fixup)
  59     *(.got1)
  60    }
  61     _etext = .;
  62     PROVIDE (etext = .);
  63     .rodata    :
  64    {
  65     *(.rodata)
  66     *(.rodata1)
  67     *(.rodata.str1.4)
  68     *(.eh_frame)
  69   }
  70   .fini      : { *(.fini)    } =0
  71   .ctors     : { *(.ctors)   }
  72   .dtors     : { *(.dtors)   }
  73
  74   /* Read-write section, merged into data segment: */
  75   . = (. + 0x00FF) & 0xFFFFFF00;
  76   _erotext = .;
  77   PROVIDE (erotext = .);
  78   .reloc   :
  79   {
  80     *(.got)
  81     _GOT2_TABLE_ = .;
  82     *(.got2)
  83     _FIXUP_TABLE_ = .;
  84     *(.fixup)
  85   }
  86   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  87   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  88
  89   .data    :
  90   {
  91     *(.data)
  92     *(.data1)
  93     *(.sdata)
  94     *(.sdata2)
  95     *(.dynamic)
  96     CONSTRUCTORS
  97   }
  98   _edata  =  .;
  99   PROVIDE (edata = .);
 100
 101   . = .;
 102   __u_boot_cmd_start = .;
 103   .u_boot_cmd : { *(.u_boot_cmd) }
 104   __u_boot_cmd_end = .;
 105
 106   . = .;
 107   __start___ex_table = .;
 108   __ex_table : { *(__ex_table) }
 109   __stop___ex_table = .;
 110
 111   . = ALIGN(256);
 112   __init_begin = .;
 113   .text.init : { *(.text.init) }
 114   .data.init : { *(.data.init) }
 115   . = ALIGN(256);
 116   __init_end = .;
 117
 118   .bootpg ADDR(.text) + 0x7f000 :
 119   {
 120     cpu/mpc85xx/start.o (.bootpg)
 121   } = 0xffff
 122
 123   .resetvec ADDR(.text) + 0x7fffc :
 124   {
 125     *(.resetvec)
 126   } = 0xffff
 127
 128   . = ADDR(.text) + 0x80000;
 129
 130   __bss_start = .;
 131   .bss (NOLOAD)       :
 132   {
 133    *(.sbss) *(.scommon)
 134    *(.dynbss)
 135    *(.bss)
 136    *(COMMON)
 137   }
 138
 139   . = ALIGN(4);
 140   _end = . ;
 141   PROVIDE (end = .);
 142 }