board/gen860t/u-boot-flashenv.lds

   1 /*
   2  * Linker command file for the GEN860T board when the environment is
   3  * stored in flash memory.
   4  *
   5  * (C) Copyright 2000-2010
   6  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   7  *
   8  * SPDX-License-Identifier:     GPL-2.0+
   9  */
  10
  11 OUTPUT_ARCH(powerpc)
  12 SECTIONS
  13 {
  14   /*
  15    * Read-only sections, merged into text segment:
  16    */
  17   . = + SIZEOF_HEADERS;
  18   .text :
  19   {
  20     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  21     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  22
  23     *(.text*)
  24   }
  25   _etext = .;
  26   PROVIDE (etext = .);
  27   .rodata    :
  28   {
  29     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  30   }
  31
  32   /*
  33    * Read-write section, merged into data segment:
  34    */
  35   . = (. + 0x00FF) & 0xFFFFFF00;
  36   _erotext = .;
  37   PROVIDE (erotext = .);
  38   .reloc   :
  39   {
  40     KEEP(*(.got))
  41     _GOT2_TABLE_ = .;
  42     KEEP(*(.got2))
  43     _FIXUP_TABLE_ = .;
  44     KEEP(*(.fixup))
  45   }
  46   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  47   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  48
  49   .data:
  50   {
  51     *(.data*)
  52     *(.sdata*)
  53   }
  54   _edata  =  .;
  55   PROVIDE (edata = .);
  56
  57   . = .;
  58
  59   .u_boot_list : {
  60         KEEP(*(SORT(.u_boot_list*)));
  61   }
  62
  63   . = .;
  64   __start___ex_table = .;
  65   __ex_table : { *(__ex_table) }
  66   __stop___ex_table = .;
  67
  68   . = ALIGN(256);
  69   __init_begin = .;
  70   .text.init : { *(.text.init) }
  71   .data.init : { *(.data.init) }
  72   . = ALIGN(256);
  73   __init_end = .;
  74
  75   __bss_start = .;
  76   .bss (NOLOAD)       :
  77   {
  78    *(.bss*)
  79    *(.sbss*)
  80    *(COMMON)
  81    . = ALIGN(4);
  82   }
  83
  84   __bss_end = . ;
  85   PROVIDE (end = .);
  86
  87   .ppcenv:
  88   {
  89     . = env_offset;
  90     common/env_embedded.o
  91   }
  92 }