board/gen860t/u-boot.lds

   1 /*
   2  * Linker command file for the GEN860T board.
   3  *
   4  * (C) Copyright 2000
   5  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_ARCH(powerpc)
  27 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  28 SECTIONS
  29 {
  30   /*
  31    * Read-only sections, merged into text segment:
  32    */
  33   . = + SIZEOF_HEADERS;
  34   .interp        : { *(.interp)         }
  35   .hash          : { *(.hash)           }
  36   .dynsym        : { *(.dynsym)         }
  37   .dynstr        : { *(.dynstr)         }
  38   .rel.text      : { *(.rel.text)       }
  39   .rela.text     : { *(.rela.text)      }
  40   .rel.data      : { *(.rel.data)       }
  41   .rela.data     : { *(.rela.data)      }
  42   .rel.rodata    : { *(.rel.rodata)     }
  43   .rela.rodata   : { *(.rela.rodata)    }
  44   .rel.got       : { *(.rel.got)        }
  45   .rela.got      : { *(.rela.got)       }
  46   .rel.ctors     : { *(.rel.ctors)      }
  47   .rela.ctors    : { *(.rela.ctors)     }
  48   .rel.dtors     : { *(.rel.dtors)      }
  49   .rela.dtors    : { *(.rela.dtors)     }
  50   .rel.bss       : { *(.rel.bss)        }
  51   .rela.bss      : { *(.rela.bss)       }
  52   .rel.plt       : { *(.rel.plt)        }
  53   .rela.plt      : { *(.rela.plt)       }
  54   .init          : { *(.init)           }
  55   .plt           : { *(.plt)            }
  56   .text :
  57   {
  58     cpu/mpc8xx/start.o          (.text)
  59     common/dlmalloc.o           (.text)
  60     lib_ppc/ppcstring.o         (.text)
  61     lib_generic/vsprintf.o      (.text)
  62     lib_generic/crc32.o         (.text)
  63     lib_generic/zlib.o          (.text)
  64
  65 /*    . = env_offset;
  66     common/environment.o(.text) */
  67
  68     *(.text)
  69     *(.fixup)
  70     *(.got1)
  71   }
  72   _etext = .;
  73   PROVIDE (etext = .);
  74   .rodata    :
  75   {
  76     *(.rodata)
  77     *(.rodata1)
  78   }
  79   .fini      : { *(.fini)    } =0
  80   .ctors     : { *(.ctors)   }
  81   .dtors     : { *(.dtors)   }
  82
  83   /*
  84    * Read-write section, merged into data segment:
  85    */
  86   . = (. + 0x00FF) & 0xFFFFFF00;
  87   _erotext = .;
  88   PROVIDE (erotext = .);
  89   .reloc   :
  90   {
  91     *(.got)
  92     _GOT2_TABLE_ = .;
  93     *(.got2)
  94     _FIXUP_TABLE_ = .;
  95     *(.fixup)
  96   }
  97   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  98   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  99
 100   .data    :
 101   {
 102     *(.data)
 103     *(.data1)
 104     *(.sdata)
 105     *(.sdata2)
 106     *(.dynamic)
 107     CONSTRUCTORS
 108   }
 109   _edata  =  .;
 110   PROVIDE (edata = .);
 111
 112   __start___ex_table = .;
 113   __ex_table : { *(__ex_table) }
 114   __stop___ex_table = .;
 115
 116   . = ALIGN(256);
 117   __init_begin = .;
 118   .text.init : { *(.text.init) }
 119   .data.init : { *(.data.init) }
 120   . = ALIGN(256);
 121   __init_end = .;
 122
 123   __bss_start = .;
 124   .bss       :
 125   {
 126    *(.sbss) *(.scommon)
 127    *(.dynbss)
 128    *(.bss)
 129    *(COMMON)
 130   }
 131
 132   _end = . ;
 133   PROVIDE (end = .);
 134 }
 135