board/gen860t/u-boot.lds

   1 /*
   2  * Linker command file for the GEN860T board.
   3  *
   4  * (C) Copyright 2000
   5  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_ARCH(powerpc)
  27 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  28 SECTIONS
  29 {
  30   /*
  31    * Read-only sections, merged into text segment:
  32    */
  33   . = + SIZEOF_HEADERS;
  34   .interp        : { *(.interp)         }
  35   .hash          : { *(.hash)           }
  36   .dynsym        : { *(.dynsym)         }
  37   .dynstr        : { *(.dynstr)         }
  38   .rel.text      : { *(.rel.text)       }
  39   .rela.text     : { *(.rela.text)      }
  40   .rel.data      : { *(.rel.data)       }
  41   .rela.data     : { *(.rela.data)      }
  42   .rel.rodata    : { *(.rel.rodata)     }
  43   .rela.rodata   : { *(.rela.rodata)    }
  44   .rel.got       : { *(.rel.got)        }
  45   .rela.got      : { *(.rela.got)       }
  46   .rel.ctors     : { *(.rel.ctors)      }
  47   .rela.ctors    : { *(.rela.ctors)     }
  48   .rel.dtors     : { *(.rel.dtors)      }
  49   .rela.dtors    : { *(.rela.dtors)     }
  50   .rel.bss       : { *(.rel.bss)        }
  51   .rela.bss      : { *(.rela.bss)       }
  52   .rel.plt       : { *(.rel.plt)        }
  53   .rela.plt      : { *(.rela.plt)       }
  54   .init          : { *(.init)           }
  55   .plt           : { *(.plt)            }
  56   .text :
  57   {
  58     cpu/mpc8xx/start.o          (.text)
  59     *(.text)
  60     *(.fixup)
  61     *(.got1)
  62   }
  63   _etext = .;
  64   PROVIDE (etext = .);
  65   .rodata    :
  66   {
  67     *(.rodata)
  68     *(.rodata1)
  69   }
  70   .fini      : { *(.fini)    } =0
  71   .ctors     : { *(.ctors)   }
  72   .dtors     : { *(.dtors)   }
  73
  74   /*
  75    * Read-write section, merged into data segment:
  76    */
  77   . = (. + 0x00FF) & 0xFFFFFF00;
  78   _erotext = .;
  79   PROVIDE (erotext = .);
  80   .reloc   :
  81   {
  82     *(.got)
  83     _GOT2_TABLE_ = .;
  84     *(.got2)
  85     _FIXUP_TABLE_ = .;
  86     *(.fixup)
  87   }
  88   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  89   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  90
  91   .data    :
  92   {
  93     *(.data)
  94     *(.data1)
  95     *(.sdata)
  96     *(.sdata2)
  97     *(.dynamic)
  98     CONSTRUCTORS
  99   }
 100   _edata  =  .;
 101   PROVIDE (edata = .);
 102
 103   __start___ex_table = .;
 104   __ex_table : { *(__ex_table) }
 105   __stop___ex_table = .;
 106
 107   . = ALIGN(256);
 108   __init_begin = .;
 109   .text.init : { *(.text.init) }
 110   .data.init : { *(.data.init) }
 111   . = ALIGN(256);
 112   __init_end = .;
 113
 114   __bss_start = .;
 115   .bss       :
 116   {
 117    *(.sbss) *(.scommon)
 118    *(.dynbss)
 119    *(.bss)
 120    *(COMMON)
 121   }
 122   _end = . ;
 123   PROVIDE (end = .);
 124 }