board/purple/u-boot.lds

   1 /*
   2  * (C) Copyright 2003
   3  * Wolfgang Denk Engineering, <wd@denx.de>
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 /*
  25 OUTPUT_FORMAT("elf32-bigmips", "elf32-bigmips", "elf32-bigmips")
  26 */
  27 OUTPUT_FORMAT("elf32-tradbigmips", "elf32-tradbigmips", "elf32-tradbigmips")
  28 OUTPUT_ARCH(mips)
  29 ENTRY(_start)
  30 SECTIONS
  31 {
  32         . = 0x00000000;
  33
  34         . = ALIGN(4);
  35         .text       :
  36         {
  37           cpu/mips/start.o              (.text)
  38           board/purple/lowlevel_init.o  (.text)
  39           cpu/mips/cache.o              (.text)
  40           common/main.o                 (.text)
  41           common/dlmalloc.o             (.text)
  42           common/cmd_boot.o             (.text)
  43           lib_generic/zlib.o            (.text)
  44           . = DEFINED(env_offset) ? env_offset : .;
  45           common/env_embedded.o (.ppcenv)
  46
  47           *(.text)
  48         }
  49
  50         . = ALIGN(4);
  51         .rodata  : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  52
  53         . = ALIGN(4);
  54         .data  : { *(.data) }
  55
  56         . = .;
  57         _gp = ALIGN(16) + 0x7ff0;
  58
  59         .got : {
  60           __got_start = .;
  61           *(.got)
  62           __got_end = .;
  63         }
  64
  65         .sdata  : { *(.sdata) }
  66
  67         .u_boot_cmd : {
  68           __u_boot_cmd_start = .;
  69           *(.u_boot_cmd)
  70           __u_boot_cmd_end = .;
  71         }
  72
  73         uboot_end_data = .;
  74         num_got_entries = (__got_end - __got_start) >> 2;
  75
  76         . = ALIGN(4);
  77         .sbss (NOLOAD)  : { *(.sbss) }
  78         .bss (NOLOAD)  : { *(.bss) . = ALIGN(4); }
  79         uboot_end = .;
  80 }