cpu/arm926ejs/start.S

   1 /*
   2  *  armboot - Startup Code for ARM926EJS CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <gj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
  13  *
  14  * See file CREDITS for list of people who contributed to this
  15  * project.
  16  *
  17  * This program is free software; you can redistribute it and/or
  18  * modify it under the terms of the GNU General Public License as
  19  * published by the Free Software Foundation; either version 2 of
  20  * the License, or (at your option) any later version.
  21  *
  22  * This program is distributed in the hope that it will be useful,
  23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25  * GNU General Public License for more details.
  26  *
  27  * You should have received a copy of the GNU General Public License
  28  * along with this program; if not, write to the Free Software
  29  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  30  * MA 02111-1307 USA
  31  */
  32
  33
  34 #include <config.h>
  35 #include <version.h>
  36
  37 #if defined(CONFIG_OMAP1610)
  38 #include <./configs/omap1510.h>
  39 #elif defined(CONFIG_OMAP730)
  40 #include <./configs/omap730.h>
  41 #endif
  42
  43 /*
  44  *************************************************************************
  45  *
  46  * Jump vector table as in table 3.1 in [1]
  47  *
  48  *************************************************************************
  49  */
  50
  51
  52 .globl _start
  53 _start:
  54         b       reset
  55         ldr     pc, _undefined_instruction
  56         ldr     pc, _software_interrupt
  57         ldr     pc, _prefetch_abort
  58         ldr     pc, _data_abort
  59         ldr     pc, _not_used
  60         ldr     pc, _irq
  61         ldr     pc, _fiq
  62
  63 _undefined_instruction:
  64         .word undefined_instruction
  65 _software_interrupt:
  66         .word software_interrupt
  67 _prefetch_abort:
  68         .word prefetch_abort
  69 _data_abort:
  70         .word data_abort
  71 _not_used:
  72         .word not_used
  73 _irq:
  74         .word irq
  75 _fiq:
  76         .word fiq
  77
  78         .balignl 16,0xdeadbeef
  79
  80
  81 /*
  82  *************************************************************************
  83  *
  84  * Startup Code (reset vector)
  85  *
  86  * do important init only if we don't start from memory!
  87  * setup Memory and board specific bits prior to relocation.
  88  * relocate armboot to ram
  89  * setup stack
  90  *
  91  *************************************************************************
  92  */
  93
  94 _TEXT_BASE:
  95         .word   TEXT_BASE
  96
  97 .globl _armboot_start
  98 _armboot_start:
  99         .word _start
 100
 101 /*
 102  * These are defined in the board-specific linker script.
 103  */
 104 .globl _bss_start
 105 _bss_start:
 106         .word __bss_start
 107
 108 .globl _bss_end
 109 _bss_end:
 110         .word _end
 111
 112 #ifdef CONFIG_USE_IRQ
 113 /* IRQ stack memory (calculated at run-time) */
 114 .globl IRQ_STACK_START
 115 IRQ_STACK_START:
 116         .word   0x0badc0de
 117
 118 /* IRQ stack memory (calculated at run-time) */
 119 .globl FIQ_STACK_START
 120 FIQ_STACK_START:
 121         .word 0x0badc0de
 122 #endif
 123
 124
 125 /*
 126  * the actual reset code
 127  */
 128
 129 reset:
 130         /*
 131          * set the cpu to SVC32 mode
 132          */
 133         mrs     r0,cpsr
 134         bic     r0,r0,#0x1f
 135         orr     r0,r0,#0xd3
 136         msr     cpsr,r0
 137
 138         /*
 139          * we do sys-critical inits only at reboot,
 140          * not when booting from ram!
 141          */
 142 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 143         bl      cpu_init_crit
 144 #endif
 145
 146 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
 147 relocate:                               /* relocate U-Boot to RAM           */
 148         adr     r0, _start              /* r0 <- current position of code   */
 149         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 150         cmp     r0, r1                  /* don't reloc during debug         */
 151         beq     stack_setup
 152
 153         ldr     r2, _armboot_start
 154         ldr     r3, _bss_start
 155         sub     r2, r3, r2              /* r2 <- size of armboot            */
 156         add     r2, r0, r2              /* r2 <- source end address         */
 157
 158 copy_loop:
 159         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 160         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 161         cmp     r0, r2                  /* until source end addreee [r2]    */
 162         ble     copy_loop
 163 #endif  /* CONFIG_SKIP_RELOCATE_UBOOT */
 164
 165         /* Set up the stack                                                 */
 166 stack_setup:
 167         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 168         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 169         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 170 #ifdef CONFIG_USE_IRQ
 171         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 172 #endif
 173         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 174
 175 clear_bss:
 176         ldr     r0, _bss_start          /* find start of bss segment        */
 177         ldr     r1, _bss_end            /* stop here                        */
 178         mov     r2, #0x00000000         /* clear                            */
 179
 180 clbss_l:str     r2, [r0]                /* clear loop...                    */
 181         add     r0, r0, #4
 182         cmp     r0, r1
 183         ble     clbss_l
 184
 185         ldr     pc, _start_armboot
 186
 187 _start_armboot:
 188         .word start_armboot
 189
 190
 191 /*
 192  *************************************************************************
 193  *
 194  * CPU_init_critical registers
 195  *
 196  * setup important registers
 197  * setup memory timing
 198  *
 199  *************************************************************************
 200  */
 201 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 202 cpu_init_crit:
 203         /*
 204          * flush v4 I/D caches
 205          */
 206         mov     r0, #0
 207         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 208         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 209
 210         /*
 211          * disable MMU stuff and caches
 212          */
 213         mrc     p15, 0, r0, c1, c0, 0
 214         bic     r0, r0, #0x00002300     /* clear bits 13, 9:8 (--V- --RS) */
 215         bic     r0, r0, #0x00000087     /* clear bits 7, 2:0 (B--- -CAM) */
 216         orr     r0, r0, #0x00000002     /* set bit 2 (A) Align */
 217         orr     r0, r0, #0x00001000     /* set bit 12 (I) I-Cache */
 218         mcr     p15, 0, r0, c1, c0, 0
 219
 220         /*
 221          * Go setup Memory and board specific bits prior to relocation.
 222          */
 223         mov     ip, lr          /* perserve link reg across call */
 224         bl      lowlevel_init   /* go setup pll,mux,memory */
 225         mov     lr, ip          /* restore link */
 226         mov     pc, lr          /* back to my caller */
 227 #endif /* CONFIG_SKIP_LOWLEVEL_INIT */
 228
 229 /*
 230  *************************************************************************
 231  *
 232  * Interrupt handling
 233  *
 234  *************************************************************************
 235  */
 236
 237 @
 238 @ IRQ stack frame.
 239 @
 240 #define S_FRAME_SIZE    72
 241
 242 #define S_OLD_R0        68
 243 #define S_PSR           64
 244 #define S_PC            60
 245 #define S_LR            56
 246 #define S_SP            52
 247
 248 #define S_IP            48
 249 #define S_FP            44
 250 #define S_R10           40
 251 #define S_R9            36
 252 #define S_R8            32
 253 #define S_R7            28
 254 #define S_R6            24
 255 #define S_R5            20
 256 #define S_R4            16
 257 #define S_R3            12
 258 #define S_R2            8
 259 #define S_R1            4
 260 #define S_R0            0
 261
 262 #define MODE_SVC 0x13
 263 #define I_BIT    0x80
 264
 265 /*
 266  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 267  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 268  */
 269
 270         .macro  bad_save_user_regs
 271         @ carve out a frame on current user stack
 272         sub     sp, sp, #S_FRAME_SIZE
 273         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
 274
 275         ldr     r2, _armboot_start
 276         sub     r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 277         sub     r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 278         @ get values for "aborted" pc and cpsr (into parm regs)
 279         ldmia   r2, {r2 - r3}
 280         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 281         add     r5, sp, #S_SP
 282         mov     r1, lr
 283         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
 284         mov     r0, sp          @ save current stack into r0 (param register)
 285         .endm
 286
 287         .macro  irq_save_user_regs
 288         sub     sp, sp, #S_FRAME_SIZE
 289         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 290         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 291         add     r8, sp, #S_PC
 292         stmdb   r8, {sp, lr}^           @ Calling SP, LR
 293         str     lr, [r8, #0]            @ Save calling PC
 294         mrs     r6, spsr
 295         str     r6, [r8, #4]            @ Save CPSR
 296         str     r0, [r8, #8]            @ Save OLD_R0
 297         mov     r0, sp
 298         .endm
 299
 300         .macro  irq_restore_user_regs
 301         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 302         mov     r0, r0
 303         ldr     lr, [sp, #S_PC]                 @ Get PC
 304         add     sp, sp, #S_FRAME_SIZE
 305         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
 306         .endm
 307
 308         .macro get_bad_stack
 309         ldr     r13, _armboot_start             @ setup our mode stack
 310         sub     r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 311         sub     r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 312
 313         str     lr, [r13]       @ save caller lr in position 0 of saved stack
 314         mrs     lr, spsr        @ get the spsr
 315         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
 316         mov     r13, #MODE_SVC  @ prepare SVC-Mode
 317         @ msr   spsr_c, r13
 318         msr     spsr, r13       @ switch modes, make sure moves will execute
 319         mov     lr, pc          @ capture return pc
 320         movs    pc, lr          @ jump to next instruction & switch modes.
 321         .endm
 322
 323         .macro get_irq_stack                    @ setup IRQ stack
 324         ldr     sp, IRQ_STACK_START
 325         .endm
 326
 327         .macro get_fiq_stack                    @ setup FIQ stack
 328         ldr     sp, FIQ_STACK_START
 329         .endm
 330
 331 /*
 332  * exception handlers
 333  */
 334         .align  5
 335 undefined_instruction:
 336         get_bad_stack
 337         bad_save_user_regs
 338         bl      do_undefined_instruction
 339
 340         .align  5
 341 software_interrupt:
 342         get_bad_stack
 343         bad_save_user_regs
 344         bl      do_software_interrupt
 345
 346         .align  5
 347 prefetch_abort:
 348         get_bad_stack
 349         bad_save_user_regs
 350         bl      do_prefetch_abort
 351
 352         .align  5
 353 data_abort:
 354         get_bad_stack
 355         bad_save_user_regs
 356         bl      do_data_abort
 357
 358         .align  5
 359 not_used:
 360         get_bad_stack
 361         bad_save_user_regs
 362         bl      do_not_used
 363
 364 #ifdef CONFIG_USE_IRQ
 365
 366         .align  5
 367 irq:
 368         get_irq_stack
 369         irq_save_user_regs
 370         bl      do_irq
 371         irq_restore_user_regs
 372
 373         .align  5
 374 fiq:
 375         get_fiq_stack
 376         /* someone ought to write a more effiction fiq_save_user_regs */
 377         irq_save_user_regs
 378         bl      do_fiq
 379         irq_restore_user_regs
 380
 381 #else
 382
 383         .align  5
 384 irq:
 385         get_bad_stack
 386         bad_save_user_regs
 387         bl      do_irq
 388
 389         .align  5
 390 fiq:
 391         get_bad_stack
 392         bad_save_user_regs
 393         bl      do_fiq
 394
 395 #endif