cpu/mpc5xxx/u-boot.lds

   1 /*
   2  * (C) Copyright 2003-2007
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .interp : { *(.interp) }
  32   .hash          : { *(.hash)           }
  33   .dynsym        : { *(.dynsym)         }
  34   .dynstr        : { *(.dynstr)         }
  35   .rel.text      : { *(.rel.text)               }
  36   .rela.text     : { *(.rela.text)      }
  37   .rel.data      : { *(.rel.data)               }
  38   .rela.data     : { *(.rela.data)      }
  39   .rel.rodata    : { *(.rel.rodata)     }
  40   .rela.rodata   : { *(.rela.rodata)    }
  41   .rel.got       : { *(.rel.got)                }
  42   .rela.got      : { *(.rela.got)               }
  43   .rel.ctors     : { *(.rel.ctors)      }
  44   .rela.ctors    : { *(.rela.ctors)     }
  45   .rel.dtors     : { *(.rel.dtors)      }
  46   .rela.dtors    : { *(.rela.dtors)     }
  47   .rel.bss       : { *(.rel.bss)                }
  48   .rela.bss      : { *(.rela.bss)               }
  49   .rel.plt       : { *(.rel.plt)                }
  50   .rela.plt      : { *(.rela.plt)               }
  51   .init          : { *(.init)   }
  52   .plt : { *(.plt) }
  53   .text      :
  54   {
  55     cpu/mpc5xxx/start.o (.text)
  56     *(.text)
  57     *(.fixup)
  58     *(.got1)
  59     . = ALIGN(16);
  60     *(.eh_frame)
  61     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  62   }
  63   .fini      : { *(.fini)    } =0
  64   .ctors     : { *(.ctors)   }
  65   .dtors     : { *(.dtors)   }
  66
  67   /* Read-write section, merged into data segment: */
  68   . = (. + 0x0FFF) & 0xFFFFF000;
  69   _erotext = .;
  70   PROVIDE (erotext = .);
  71   .reloc   :
  72   {
  73     *(.got)
  74     _GOT2_TABLE_ = .;
  75     *(.got2)
  76     _FIXUP_TABLE_ = .;
  77     *(.fixup)
  78   }
  79   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  80   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  81
  82   .data    :
  83   {
  84     *(.data)
  85     *(.data1)
  86     *(.sdata)
  87     *(.sdata2)
  88     *(.dynamic)
  89     CONSTRUCTORS
  90   }
  91   _edata  =  .;
  92   PROVIDE (edata = .);
  93
  94   . = .;
  95   __u_boot_cmd_start = .;
  96   .u_boot_cmd : { *(.u_boot_cmd) }
  97   __u_boot_cmd_end = .;
  98
  99
 100   . = .;
 101   __start___ex_table = .;
 102   __ex_table : { *(__ex_table) }
 103   __stop___ex_table = .;
 104
 105   . = ALIGN(4096);
 106   __init_begin = .;
 107   .text.init : { *(.text.init) }
 108   .data.init : { *(.data.init) }
 109   . = ALIGN(4096);
 110   __init_end = .;
 111
 112   __bss_start = .;
 113   .bss (NOLOAD)       :
 114   {
 115    *(.sbss) *(.scommon)
 116    *(.dynbss)
 117    *(.bss)
 118    *(COMMON)
 119    . = ALIGN(4);
 120   }
 121   _end = . ;
 122   PROVIDE (end = .);
 123 }